MSXML ServerXMLHTTP- service Web appelant

Question

Problème: j'obtiens la sortie d'erreur suivante de If Err.Number <> 0 Then check;

Err.Number :-1072954818 
Err.Source :msxml6.dll 
Err.Source :This method cannot be called until the open method has been called. 

code:

dim objHttpRequest 
dim gw_menu_request 
dim HTTPMethod 

HTTPMethod="POST" 
Set objHttpRequest = Server.CreateObject("MSXML2.ServerXMLHTTP.6.0")  
gw_menu_request = "http://test.com?q=headerexpose/expose_headers/expose_json"  
objHttpRequest.setRequestHeader "Content-Type", "application/x-www-form-urlencoded" 
objHttpRequest.setRequestHeader "Content-Length", 0 
objHttpRequest.open HTTPMethod, gw_menu_request, false   
Response.write(objHttpRequest.ResponseXML) 

If Err.Number <> 0 Then 
    Response.Write "Err.Number :" & Err.Number & "<br/>" 
    Response.Write "Err.Source :" & Err.Source & "<br/>" 
    Response.Write "Err.Source :" & Err.Description & "<br/>" 
    Response.Write "Err.File :" & Err.File & "<br/>" 
End If 

Qu'est-ce que je manque ici?

Answer 1

Le problème est exactement comme décrit dans l'erreur, vous essayez de définir des en-têtes de demande sans d'abord appeler Open(). Il vous manque également la méthode Send() pour envoyer la demande avant qu'une réponse puisse être reçue.

Dim objHttpRequest 
Dim gw_menu_request 
Dim HTTPMethod 

HTTPMethod="POST" 
Set objHttpRequest = Server.CreateObject("MSXML2.ServerXMLHTTP.6.0")  
gw_menu_request = "http://test.com?q=headerexpose/expose_headers/expose_json" 
'Open request specifying method and URL to call 
objHttpRequest.open HTTPMethod, gw_menu_request, False 
'Set any HTTP headers needed before sending.  
objHttpRequest.setRequestHeader "Content-Type", "application/x-www-form-urlencoded" 
objHttpRequest.setRequestHeader "Content-Length", 0 
'Send the request 
objHttpRequest.Send 
Response.write(objHttpRequest.ResponseXML.Xml) 

If Err.Number <> 0 Then 
    Response.Write "Err.Number :" & Err.Number & "<br/>" 
    Response.Write "Err.Source :" & Err.Source & "<br/>" 
    Response.Write "Err.Source :" & Err.Description & "<br/>" 
    Response.Write "Err.File :" & Err.File & "<br/>" 
End If 

Vous voulez également ResponseXML.Xml ou vous recevrez un

Microsoft VBScript runtime error: Type mismatch

parce que vous essayez de sortir l'objet non la propriété Xml qui contient la représentation de chaîne XML.