Comportement du mot clé VB.NET WithEvents - Restriction du compilateur VB.NET?

Question

Je travaille à devenir aussi familier avec C# que je le suis avec VB.NET (la langue utilisée sur mon lieu de travail). Une des meilleures choses à propos du processus d'apprentissage est qu'en apprenant l'autre langue, vous avez tendance à en apprendre davantage sur votre langue maternelle - de petites questions comme celle-ci apparaissent:

D'après les sources que j'ai trouvées et passées expérience, un champ dans VB.NET déclaré WithEvents est capable de déclencher des événements. Je comprends que C# n'a pas un équivalent direct - mais ma question est: champs sans ce mot-clé dans VB.NET ne peut pas élever des événements, est-il un moyen de créer ce même comportement en C#? Est-ce que le compilateur VB bloque simplement ces objets de la gestion de leurs événements (tout en leur permettant de déclencher des événements comme d'habitude)?

Je suis juste curieux; Je n'ai aucune application particulière pour la question ...

Answer 1

Omettre WithEvents ne bloque pas les membres d'élever des événements. Cela vous empêche d'utiliser le mot clé 'handles' sur leurs événements.

Voici une utilisation typique de WithEvents:

Class C1 
    Public WithEvents ev As New EventThrower() 
    Public Sub catcher() Handles ev.event 
     Debug.print("Event") 
    End Sub 
End Class 

Voici une classe qui n'utilise pas WithEvents et est à peu près équivalent. Cela démontre pourquoi WithEvents est très utile:

Class C2 
    Private _ev As EventThrower 
    Public Property ev() As EventThrower 

     Get 
      Return _ev 
     End Get 

     Set(ByVal value As EventThrower) 
      If _ev IsNot Nothing Then 
        removehandler _ev.event, addressof catcher 
      End If 
      _ev = value 
      If _ev IsNot Nothing Then 
        addhandler _ev.event, addressof catcher 
      End If 
     End Set 
    End Property 

    Public Sub New() 
     ev = New EventThrower() 
    End Sub 

    Public Sub catcher() 
     Debug.print("Event") 
    End Sub 
End Class