XSLT trouver un mot près d'un autre mot

Question

Comment puis-je trouver, avec XSLT, le mot avant et après un autre mot connu dans un nœud de texte?

Answer 1

I. Dans XSLT 2.x 2.x/XPath, on peut utiliser les fonctions tokenize() et index-of() pour produire les résultats désirés avec une XPath-liner expressions:

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="text"/> 

<xsl:param name="pWord" select="'three'"/> 

<xsl:template match="text()"> 
    <xsl:sequence select= 
    "tokenize(., ',\s*') 
     [index-of(tokenize(current(), ',\s*'), $pWord) -1]"/> 

    <xsl:sequence select= 
    "tokenize(., ',\s*') 
     [index-of(tokenize(current(), ',\s*'), $pWord) +1]"/> 
</xsl:template> 
</xsl:stylesheet> 

Lorsque cette transformation est appliqué sur le document XML suivant:

<t>One, two, three, four</t> 

le résultat recherché, correct produit:

two four 

II. XSLT 1.0 solution

Il est possible de résoudre la même tâche dans XSLT 1.0 à l'aide du modèle strSplit-to-Words de FXSL.

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:ext="http://exslt.org/common" 
> 
    <xsl:import href="strSplit-to-Words.xsl"/> 

    <xsl:output method="text"/> 

    <xsl:param name="pWord" select="'three'"/> 

    <xsl:template match="/"> 
     <xsl:variable name="vrtfwordNodes"> 
     <xsl:call-template name="str-split-to-words"> 
      <xsl:with-param name="pStr" select="/"/> 
      <xsl:with-param name="pDelimiters" 
          select="', &#9;&#10;&#13;'"/> 
     </xsl:call-template> 
     </xsl:variable> 

     <xsl:variable name="vwordNodes" 
     select="ext:node-set($vrtfwordNodes)/*"/> 

     <xsl:variable name="vserchWordPos" select= 
     "count($vwordNodes 
       [. = $pWord]/preceding-sibling::* 
      ) +1"/> 

     <xsl:value-of select= 
     "concat($vwordNodes[$vserchWordPos -1], 
       ' ', 
       $vwordNodes[$vserchWordPos +1] 
       ) 
     "/> 
    </xsl:template> 
</xsl:stylesheet> 

Lorsque cette transformation est appliquée sur le même document XML:

<t>One, two, three, four</t> 

le résultat recherché, correct est produit:

two four