Quelle est la meilleure façon de supprimer les espaces après un certain caractère dans une chaîne?

Question

J'essaie de construire une liste qui sera utilisée comme la clause in d'une instruction select. L'exigence est que l'utilisateur entre une liste de descriptions séparées par des virgules. Chaque description peut contenir des espaces, donc je ne peux pas supprimer les espaces avant de diviser par une virgule pour ajouter les guillemets simples autour de chaque description. Je veux supprimer tout l'espace blanc après une seule citation puisque aucune description ne commencera avec un espace. Quelle est la meilleure façon de le faire dans VB.NET? Expression régulière ou une fonction de chaîne? Voici ce que j'ai jusqu'à présent .:

Partial Class Test 
    Inherits System.Web.UI.Page 

    Protected Sub cmdGetParts_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles cmdGetParts.Click 
     Dim sDescriptionList As String = "" 
     BuildList(sDescriptionList) 
     RemoveSpacesFromList(sDescriptionList) 
     FillGrid(sDescriptionList) 
    End Sub 

    'Build descriptions List based on txtDescriptionList.Text 
    Private Sub BuildList(ByRef sDescriptionList As String) 
     Dim sDescriptionArray As String() 
     sDescriptionArray = txtDescriptionList.Text.Trim.Split(","c) 
     Dim iStringCount As Integer = 0 
     For Each description In sDescriptionArray 
      If iStringCount > 0 Then 
       sDescriptionList = sDescriptionList & "," 
      End If 
      sDescriptionList = sDescriptionList & "'" & description & "'" 
      iStringCount = iStringCount + 1 
     Next 
    End Sub 

    **'This procedure removes unwanted spaces from description list 
    Private Sub RemoveSpacesFromList(ByRef sList As String) 
     sList = sList.Replace("' ", "'") 
    End Sub** 

    'This procedure fills the grid with data for descriptions passed in 
    Private Sub FillGrid(ByVal sDescriptionList As String) 
     Dim bo As New boPart 
     Dim dtParts As Data.DataTable 
     dtParts = bo.GetPartByDescriptionList(sDescriptionList) 
     GridView1.DataSource = dtParts 
     GridView1.DataBind() 
    End Sub 
End Class 

Modifié: Après avoir examiné ce code, je pense que je peux être en mesure de placer juste description.Trim l'intérieur de la boucle For Each de la procédure construitListe.

Answer 1

Utilisez une expression régulière pour faire correspondre une virgule avec n'importe quel espace blanc environnant et remplacez par des apostropes et une virgule. L'apostrope de départ pour le premier objet et l'apostrophe de fin pour le dernier objet que vous ajoutez simplement après.

La méthode RemoveSpacesFromList n'est plus nécessaire, car la méthode BuildList fait tout.

Protected Sub cmdGetParts_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles cmdGetParts.Click 
    Dim descriptions As String = txtDescriptionList.Text 
    descriptions = BuildList(descriptions) 
    FillGrid(descriptions) 
End Sub 

''//Build descriptions List based on a comma separated string 
Private Function BuildList(ByVal descriptions As String) As String 
    Return "'" + Regex.Replace(descriptions, "\s*,\s*", "','", RegexOptions.Compiled) + "'" 
End Function 

Note:
Si vous utilisez cette chaîne pour construire une requête SQL, votre application est grande ouverte pour des attaques par injection SQL. L'utilisation de requêtes paramétrées est la méthode préférée, mais cela peut ne pas être pratique dans votre cas. L'entrée de l'utilisateur doit au moins être nettoyée avant d'être utilisée dans une requête.

Edit:
Si l'adaptateur utilise l'apostrophe comme caractère d'échappement dans une chaîne littérale, vous pouvez échapper à la chaîne correctement comme ceci:

Private Function BuildList(ByVal descriptions As String) As String 
    Return "'" + Regex.Replace(descriptions.Replace("'","''"), "\s*,\s*", "','", RegexOptions.Compiled) + "'" 
End Function 

Answer 2

Tant que vous ne pouvez pas avoir intégré des guillemets simples, ce qui suit devrait faire l'affaire

Dim replaced = Regex.Replace(input, "'\s+", "'") 

La chaîne regex '\s+ correspondra à une seule citation suivie par un ou plusieurs caractères blancs. Toutes les instances de ce match seront remplacées par un seul devis.