Trouver la partie répertoire (moins le nom de fichier) d'un chemin d'accès complet en accès 97

Question

Pour diverses raisons, je suis coincé dans Access 97 et n'ai besoin que de la partie path d'un chemin d'accès complet.

Par exemple, le nom

c:\whatever dir\another dir\stuff.mdb 

devrait devenir

c:\whatever dir\another dir\ 

Ce site a quelques suggestions sur la façon de le faire: http://www.ammara.com/access_image_faq/parse_path_filename.html

Mais ils semblent plutôt hideux. Il doit y avoir un meilleur moyen, non?

Answer 1

C'est à peu près tout. Il n'y a pas de fonction intégrée magique ...

Answer 2

J'ai toujours utilisé le FileSystemObject pour ce genre de chose. Voici une petite fonction d'emballage que j'ai utilisée. Veillez à référencer le Microsoft Scripting Runtime.

Function StripFilename(sPathFile As String) As String 

'given a full path and file, strip the filename off the end and return the path 

Dim filesystem As New FileSystemObject 

StripFilename = filesystem.GetParentFolderName(sPathFile) & "\" 

Exit Function 

End Function 

Answer 3

gauche (currentdb.Name, instr (1, currentdb.Name, dir (currentdb.Name)) - 1)

La fonction Dir renvoie uniquement la partie de fichier du chemin complet. Currentdb.Name est utilisé ici, mais il peut s'agir de n'importe quelle chaîne de chemin complet.

Answer 4

Si vous avez juste besoin du chemin de la MDB actuellement ouvert dans l'interface utilisateur Access, je suggérerais d'écrire une fonction qui analyse CurrentDB.Name, puis stocke le résultat dans une variable statique à l'intérieur de la fonction. Quelque chose comme ceci:

Public Function CurrentPath() As String 
    Dim strCurrentDBName As String 
    Static strPath As String 
    Dim i As Integer 

    If Len(strPath) = 0 Then 
    strCurrentDBName = CurrentDb.Name 
    For i = Len(strCurrentDBName) To 1 Step -1 
     If Mid(strCurrentDBName, i, 1) = "\" Then 
      strPath = Left(strCurrentDBName, i) 
      Exit For 
     End If 
    Next 
    End If 
    CurrentPath = strPath 
End Function 

Ceci a l'avantage qu'il boucle seulement le nom une fois.

Bien sûr, cela ne fonctionne qu'avec le fichier ouvert dans l'interface utilisateur.

Une autre façon d'écrire serait d'utiliser les fonctions prévues à l'link intérieur de la fonction ci-dessus, ainsi:

Public Function CurrentPath() As String 
    Static strPath As String 

    If Len(strPath) = 0 Then 
    strPath = FolderFromPath(CurrentDB.Name) 
    End If 
    CurrentPath = strPath 
End Function 

Cela rend la récupération du chemin courant très efficace alors que le code utilisant qui peut être utilisé pour trouver le chemin pour n'importe quel nom de fichier/chemin.

Answer 5

Cela semble fonctionner. Ce qui précède ne figure pas dans Excel 2010.

Function StripFilename(sPathFile As String) As String 
'given a full path and file, strip the filename off the end and return the path 
Dim filesystem As Object 

Set filesystem = CreateObject("Scripting.FilesystemObject") 

StripFilename = filesystem.GetParentFolderName(sPathFile) & "\" 

Exit Function 

End Function 

Answer 6

Essayez cette fonction:

Function FolderPath(FilePath As String) As String 

    '-------------------------------------------------- 
    'Returns the folder path form the file path. 

    'Written by: Christos Samaras 
    'Date:   06/11/2013 
    '-------------------------------------------------- 

    Dim FileName As String 

    With WorksheetFunction 
     FileName = Mid(FilePath, .Find("*", .Substitute(FilePath, "\", "*", Len(FilePath) - _ 
        Len(.Substitute(FilePath, "\", "")))) + 1, Len(FilePath)) 
    End With 

    FolderPath = Left(FilePath, Len(FilePath) - Len(FileName) - 1) 

End Function

Si vous ne souhaitez pas supprimer la dernière barre oblique inverse « \ » à la fin du chemin du dossier, modifiez la dernière ligne avec ceci:

FolderPath = Left(FilePath, Len(FilePath) - Len(FileName))

Exemple:

FolderPath("C:\Users\Christos\Desktop\LAT Analysers Signal Correction\1\TP 14_03_2013_5.csv") 

donne:

C: \ Users \ Christos \ Desktop \ LAT Analyseurs de correction de signal \ 1

ou

C: \ Users \ Christos \ Desktop \ LAT Analyseurs de correction de signal \ 1 \

dans le second cas (notez qu'il y a un backslash à la fin). Je souhaite que cela aide ...

Answer 7

Public Function GetDirectoryName(ByVal source As String) As String() 
Dim fso, oFolder, oSubfolder, oFile, queue As Collection 
Set fso = CreateObject("Scripting.FileSystemObject") 
Set queue = New Collection 

Dim source_file() As String 
Dim i As Integer   

queue.Add fso.GetFolder(source) 'obviously replace 

Do While queue.Count > 0 
    Set oFolder = queue(1) 
    queue.Remove 1 'dequeue 
    '...insert any folder processing code here... 
    For Each oSubfolder In oFolder.SubFolders 
     queue.Add oSubfolder 'enqueue 
    Next oSubfolder 
    For Each oFile In oFolder.Files 
     '...insert any file processing code here... 
     'Debug.Print oFile 
     i = i + 1 
     ReDim Preserve source_file(i) 
     source_file(i) = oFile 
    Next oFile 
Loop 
GetDirectoryName = source_file 
End Function 

Et là, vous pouvez appeler la fonction:

Sub test() 
Dim s 
For Each s In GetDirectoryName("C:\New folder") 
Debug.Print s 
Next 
End Sub 

Answer 8

Vous pouvez faire quelque chose de simple comme: Left(path, InStrRev(path, "\"))

Exemple:

Function GetDirectory(path) 
    GetDirectory = Left(path, InStrRev(path, "\")) 
End Function