Comment obtenir les rôles/droits ACL possibles sur un dossier utilisant CMD?

Question

Je voudrais savoir comment obtenir les droits possibles sur un dossier en utilisant cmd?

Je vais essayer d'expliquer plus mon besoin afin que vous comprendrez ma question:

J'utilise icacls changer ACL sur MyFolder.

J'utilise une commande comme celui-ci:

icacls "%ProgramFiles(x86)%\MyFolder" /grant:r Administrators:F 

ou

icacls "%ProgramFiles(x86)%\MyFolder" /grant:r Users:(OI)(CI)F /t /c 

Le problème est que si je lance que sur un ordinateur français, il me donne une erreur d'approbation quelque chose comme: " La relation d'approbation entre ce poste de travail et le domaine principal a échoué "....

Après avoir effectué quelques tests, j'ai compris que le problème est que j'utilise des administrateurs et je J'ai dû utiliser Administrateur (lors de l'exécution de mon script sur un Windows français). Même chose pour "Utilisateurs", je devrais utiliser "Utilisateurs" et non "Utilisateurs" dans ma commande pour que cela fonctionne. Ce dont j'ai besoin c'est de savoir s'il y a une variable utilisée par windows pour m'aider pour la localisation, pour obtenir automatiquement les rôles en utilisant cmd, pour remplacer "Administrators", "Users" par cette variable, pour que mon code fonctionne sur tout ordinateur Windows est tout c'est la langue ...

ce que je besoin est quelque chose comme:

icacls "%ProgramFiles(x86)%\MyFolder" /grant:r %Admin%:F 


icacls "%ProgramFiles(x86)%\MyFolder" /grant:r %Users%:F 

% de sorte que l'administrateur% sera automatiquement remplacé par les administrateurs sur un ordinateur anglais et par sur un ordinateur Administrateur français etc.

La syntaxe complète que j'utilise est en fait:

icacls "%ProgramFiles(x86)%\MYFOLDER" /grant:r Administrators:F /grant:r SYSTEM:F /grant Users:(OI)(CI)F /t /c 

Answer 1

Vous pouvez utiliser le well known SID string constants

icacls "%ProgramFiles(x86)%\MyFolder" /grant:r *BA:F 

Si les noms sont nécessaires pour d'autres utilisations, vous pouvez demander à WMI pour le nécessaire information

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    for /f "tokens=2 delims==" %%a in (' 
     wmic path WIN32_UserAccount 
     where ( 
        LocalAccount^="True" 
        And SID Like "S-1-5-21-%%-500" 
       ^) 
     get Name /value 
    ') do for /f delims^=^ eol^= %%b in ("%%a") do set "adminName=%%b" 

    echo Local administrator account = [%adminName%] 


    for /f "tokens=2 delims==" %%a in (' 
     wmic path WIN32_Group 
     where (
        SID Like "S-1-5-32-544" 
       ^) 
     get  Name /value 
    ') do for /f delims^=^ eol^= %%b in ("%%a") do set "adminGroup=%%b" 

    echo Local administrators group = [%adminGroup%] 


    for /f "tokens=2 delims==" %%a in (' 
     wmic path WIN32_Group 
     where (
        SID Like "S-1-5-32-545" 
       ^) 
     get  Name /value 
    ') do for /f delims^=^ eol^= %%b in ("%%a") do set "usersGroup=%%b" 

    echo Local users group   = [%usersGroup%]