Le graphique vba Excel 2003 a échoué

Question

Donc im obtenir un échec de graphique a échoué et il semble que ce soit à cause de mon nom WBname, mais je ne peux pas le comprendre. J'ai eu une question similaire plus tôt mais comme c'est un peu différent, j'ai pensé que je ferais une nouvelle question. Voici le code im ayant des problèmes avec:

Dim WBname As String 
WBname = Replace(ActiveWorkbook.Name, ".xls", "") 
Worksheets(WBname).Activate 
Charts.Add 
ActiveChart.ChartType = xlXYScatterSmoothNoMarkers 
ActiveChart.SeriesCollection(1).XValues = Worksheets(WBname).Range("A4:A5000") 
ActiveChart.SeriesCollection(1).Values = Worksheets(WBname).Range("B4:B5000") 
ActiveChart.SeriesCollection(1).Name = Worksheets(WBname).Range("B3") 
ActiveChart.SeriesCollection.NewSeries 
ActiveChart.SeriesCollection(2).XValues = Worksheets(WBname).Range("A4:A5000") 
ActiveChart.SeriesCollection(2).Values = Worksheets(WBname).Range("C4:C5000") 
ActiveChart.SeriesCollection(2).Name = Worksheets(WBname).Range("C3") 
ActiveChart.SeriesCollection.NewSeries 
ActiveChart.SeriesCollection(3).XValues = Worksheets(WBname).Range("A4:A5000") 
ActiveChart.SeriesCollection(3).Values = Worksheets(WBname).Range("D4:D5000") 
ActiveChart.SeriesCollection(3).Name = Worksheets(WBname).Range("D3") 
ActiveChart.SeriesCollection.NewSeries 
ActiveChart.SeriesCollection(4).XValues = Worksheets(WBname).Range("A4:A5000") 
ActiveChart.SeriesCollection(4).Values = Worksheets(WBname).Range("I4:I5000") 
ActiveChart.SeriesCollection(4).Name = Worksheets(WBname).Range("I3") 

WBname sort comme je veux mais je reçois toujours des erreurs.

Method 'SeriesCollection' of object '_Chart' Failed 

Le nom de la feuille change dynamiquement et correspond au nom WB FYI.

EDIT: i ajouté

ActiveChart.SetSourceData Source:=Sheets(WBname).Range("A4:A5000") 

et il semble fonctionner

Answer 1

Vous obtenez cette erreur parce que vous essayez d'attribuer des valeurs à la série qui est pas là;)

Vous devez d'abord ajouter la série, puis lui affecter des valeurs. Voir cet exemple

Sub Sample() 
    Dim WBname As String 
    WBname = Replace(ActiveWorkbook.Name, ".xls", "") 
    Worksheets(WBname).Activate 

    Charts.Add 
    ActiveChart.ChartType = xlXYScatterSmoothNoMarkers 

    ActiveChart.SeriesCollection.NewSeries '<~~~~~ SEE THIS 

    ActiveChart.SeriesCollection(1).XValues = Worksheets(WBname).Range("A4:A5000") 
    ActiveChart.SeriesCollection(1).Values = Worksheets(WBname).Range("B4:B5000") 
    ActiveChart.SeriesCollection(1).Name = Worksheets(WBname).Range("B3") 
End Sub 

FOLLOWUP

Vous obtenez série sometimes supplémentaire parce que votre curseur se trouve dans les données, par exemple dans la cellule B5 ou I10 ou d'une autre cellule. Excel par défaut ajoute la série lorsque vous dites Charts.Add dans un tel scénario. Assurez-vous qu'aucune de vos données n'est sélectionnée lorsque vous exécutez la macro. Une alternative consiste à supprimer la collection de la série après Charts.Add. Voir cet exemple

Sub Sample() 
    Dim WBname As String 
    Dim i As Long 

    WBname = Replace(ActiveWorkbook.Name, ".xls", "") 
    Worksheets(WBname).Activate 
    Charts.Add 

    With ActiveChart 
     On Error Resume Next 
     For i = .SeriesCollection.Count To 1 Step -1 
      .SeriesCollection(i).Delete 
     Next i 
     On Error GoTo 0 

     .ChartType = xlXYScatterSmoothNoMarkers 

     .SeriesCollection.NewSeries 
     .SeriesCollection(1).XValues = Worksheets(WBname).Range("A4:A5000") 
     .SeriesCollection(1).Values = Worksheets(WBname).Range("B4:B5000") 
     .SeriesCollection(1).Name = Worksheets(WBname).Range("B3") 

     .SeriesCollection.NewSeries 
     .SeriesCollection(2).XValues = Worksheets(WBname).Range("A4:A5000") 
     .SeriesCollection(2).Values = Worksheets(WBname).Range("C4:C5000") 
     .SeriesCollection(2).Name = Worksheets(WBname).Range("C3") 

     .SeriesCollection.NewSeries 
     .SeriesCollection(3).XValues = Worksheets(WBname).Range("A4:A5000") 
     .SeriesCollection(3).Values = Worksheets(WBname).Range("D4:D5000") 
     .SeriesCollection(3).Name = Worksheets(WBname).Range("D3") 

     .SeriesCollection.NewSeries 
     .SeriesCollection(4).XValues = Worksheets(WBname).Range("A4:A5000") 
     .SeriesCollection(4).Values = Worksheets(WBname).Range("I4:I5000") 
     .SeriesCollection(4).Name = Worksheets(WBname).Range("I3") 
    End With 
End Sub 

Answer 2

Vous ne dites pas ce que vous voulez feuille travailler. (en supposant que le classeur est vraiment nécessaire, ce n'est pas le cas la plupart du temps):

Workbooks(WBname).Sheets("Sheet1").Range("A4:A5000") 

devrait fonctionner mieux.

(dans ces cas, il suffit d'utiliser l'enregistreur de macro pour obtenir la bonne façon de le faire et l'adapter à vos besoins après)