Loop Through PSTs dans Outlook 2003 avec VBA

Question

dans Outlook 2007, je suis en mesure de boucler dans les magasins de mails, y compris PSTs, en utilisant le code comme ceci:

Dim stores As Outlook.stores 
Set stores = objNamespace.stores 
Dim store As Outlook.store 

For Each store In stores 
    MsgBox store.FilePath 
Next 

Cependant, dans Outlook 2003, le Outlook.store et Les objets Outlook.stores n'existent pas.

Existe-t-il des objets équivalents dans Outlook 2003? Quelle autre méthode puis-je utiliser pour faire une boucle dans les magasins de messagerie?

Merci.

Answer 1

Cet exemple de code pour Outlook 2003 parcourt les boîtes aux lettres de niveau supérieur et imprime certaines propriétés dans la fenêtre Exécution. J'ai choisi les propriétés qui semblaient les plus utiles en fonction de votre demande.

Sub LoopThruMailboxes() 

Dim olApp As Outlook.Application 
Dim olNS As Outlook.NameSpace 
Dim mailboxCount As Long 
Dim i As Long 
Dim folder As Outlook.MAPIFolder 

' get local namespace 
Set olApp = Outlook.Application 
Set olNS = olApp.GetNamespace("MAPI") 

mailboxCount = olNS.Folders.count 

For i = 1 To mailboxCount 
    Set folder = olNS.Folders(i) 

    Debug.Print folder.EntryID 
    Debug.Print folder.StoreID 
    Debug.Print folder.Name 
    Debug.Print folder.FolderPath 
Next i 

End Sub 

folder.Name est le nom de la boîte aux lettres, folder.StoreID est l'ID de magasin (je ne suis pas sûr de ce que vous vouliez dire par « chemin du fichier de magasin », je ne vois rien cela semblait pertinent de toute façon).

est ici une version functionized qui retourne le nom du dossier et l'ID de magasin comme un tableau, que vous pouvez attribuer directement à une zone de liste:

Function GetMailBoxInfo() As String() 

Dim olApp As Outlook.Application 
Dim olNS As Outlook.NameSpace 
Dim mailboxCount As Long 
Dim i As Long 
Dim folder As Outlook.MAPIFolder 
Dim tempString() As String 

' get local namespace 
Set olApp = Outlook.Application 
Set olNS = olApp.GetNamespace("MAPI") 

mailboxCount = olNS.Folders.count 

' size array accordingly 
ReDim tempString(1 To mailboxCount, 1 To 2) 

For i = 1 To mailboxCount 
    Set folder = olNS.Folders(i) 

    tempString(i, 1) = folder.Name 
    tempString(i, 2) = folder.StoreID 
Next i 

    GetMailBoxInfo = tempString 

End Function 

ex:

ListBox1.List = GetMailBoxInfo