Groupe XSLT en utilisant 2 éléments différents

Question

Je suis nouveau sur xslt. J'essaye de grouper par 2 éléments différents. D'abord par travailleur, puis par code de paie. S'il vous plaît voir que la somme des montants à cause du groupe par code de paie. Ci-dessous est un échantillon avant xsl, puis un échantillon après xsl que je voudrais en sortie.

Avant:

<?xml version='1.0' encoding='utf-8'?> 
<File xmlns:is="java:com.workday.esb.intsys.xpath.ParsedIntegrationSystemFunctions" 
    xmlns:tv="java:com.workday.esb.intsys.TypedValue"> 
    <Worker> 
     <Detail> 
      <EmployeeID>0008765</EmployeeID> 
      <FirstName>ROBERT</FirstName> 
      <PayCode>RSVEST</PayCode> 
      <Amount>5572.800000</Amount> 
     </Detail> 
     <Detail> 
      <EmployeeID>0008765</EmployeeID> 
      <FirstName>ROBERT</FirstName> 
      <PayCode>FICA</PayCode> 
      <Amount>40.000000</Amount> 
     </Detail> 
    </Worker> 
    <Worker> 
     <Detail> 
      <EmployeeID>0008765</EmployeeID> 
      <FirstName>ROBERT</FirstName> 
      <PayCode>RSVEST</PayCode> 
      <Amount>13545.000000</Amount> 
     </Detail> 
    </Worker> 
    <Worker> 
     <Detail> 
      <EmployeeID>00</EmployeeID> 
      <FirstName>RUSSELL</FirstName> 
      <PayCode>RSVEST</PayCode> 
      <Amount>84811.050000</Amount> 
     </Detail> 
    </Worker> 
</File> 

Ce que je voudrais en sortie, d'abord par le regroupement des travailleurs, puis par groupe Code de paie. Montants somme en raison du groupement:

<?xml version='1.0' encoding='utf-8'?> 
<File xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:tv="java:com.workday.esb.intsys.TypedValue"> 
    <Worker> 
     <Detail> 
      <EmployeeID>0008765</EmployeeID> 
      <FirstName>ROBERT</FirstName> 
      <PayCode>RSVEST</PayCode> 
      <Amount>19117.800000</Amount> 
     </Detail> 
     <Detail> 
      <EmployeeID>0008765</EmployeeID> 
      <FirstName>ROBERT</FirstName> 
      <PayCode>FICA</PayCode> 
      <Amount>40.000000</Amount> 
     </Detail> 
    </Worker> 
    <Worker> 
     <Detail> 
      <EmployeeID>00</EmployeeID> 
      <FirstName>RUSSELL</FirstName> 
      <PayCode>RSVEST</PayCode> 
      <Amount>84811.050000</Amount> 
     </Detail> 
    </Worker> 
</File> 

Ci-dessous mon XSL qui ne fonctionne pas:

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="2.0" exclude-result-prefixes="xsl wd xsd this env" 
    xmlns:wd="urn:com.workday/bsvc" 
    xmlns:xsd="http://www.w3.org/2001/XMLSchema" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:env="http://schemas.xmlsoap.org/soap/envelope/" 
    xmlns:this="urn:this-stylesheet"> 

    <xsl:output indent="yes" method="xml"/> 
    <xsl:template match="/">  
     <File> 
      <Worker> 
       <xsl:for-each-group select="File" group-by="Worker"> 
        <Detail>    
         <EmployeeID><xsl:value-of select="Worker/current-group()/EmployeeID"></xsl:value-of></EmployeeID> 
         <FirstName><xsl:value-of select="//current-group()//FirstName"></xsl:value-of></FirstName> 
         <PayCode><xsl:value-of select="PayCode"></xsl:value-of></PayCode> 
         <Amount><xsl:value-of select="format-number(sum(current-group()/number(translate(Amount,',',''))),'######.00')"></xsl:value-of></Amount> 
        </Detail> 
       </xsl:for-each-group> 
      </Worker> 
     </File> 
    </xsl:template> 
</xsl:stylesheet> 

Quelqu'un peut-il s'il vous plaît mettre un SL qui transformera ci-dessus à la sortie désirée?
J'ai travaillé dessus pendant des heures et agitant le drapeau blanc lol.

Merci!

Answer 1

Si vous voulez avoir un groupe pour chaque EmployeeID, et dans chacun de ces groupes un sous-groupe pour chaque PayCode, alors vous devez évidemment nicher deuxxsl:for-each-group instructions. Et les nœuds que vous devez regrouper sont les éléments Detail, pas l'élément racine File dont il n'y en aura qu'un seul.

XSLT 2,0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="/File">  
    <xsl:copy> 
     <xsl:for-each-group select="Worker/Detail" group-by="EmployeeID"> 
      <Worker> 
       <xsl:for-each-group select="current-group()" group-by="PayCode"> 
        <Detail>    
         <xsl:copy-of select="EmployeeID | FirstName | PayCode"/> 
         <Amount> 
          <xsl:value-of select="format-number(sum(current-group()/Amount),'#.000000')"/> 
         </Amount> 
        </Detail> 
       </xsl:for-each-group> 
      </Worker> 
     </xsl:for-each-group> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet>