Valeurs uniques Select/Output

Question

Je dois parcourir un document XML (pas de problème là-bas) et vérifier si une valeur que je trouve est déjà dans une balise (a) dans un div dans mon document XSL que je génère, seulement si la valeur n'est pas dans ce (a) tag je devrais créer un nouveau (a) tag pour cela et mettre dans le div que je vérifie ... Quelqu'un sait comment le faire dynamiquement dans XSLT?

<div id="tags"><span class="l_cap">&#160;</span> 
<a href="#" class="current">all</a> 
<xsl:for-each select="root/nodes/node/data/genres"> 
    <xsl:for-each select="value"> 
    **<xsl:if test="not(contains())">** 
     <a href="#"><xsl:value-of select="current()"/></a> 
    </xsl:if> 
    </xsl:for-each> 
</xsl:for-each> 

 

désolé pour avant, ce que je suis en train de faire est la suivante: dans l'instruction if, vérifiez si la valeur actuelle est existe déjà dans la div sinon, ajoutez, si est, don « ai rien faire ...

10x à nouveau

Answer 1

On dirait que vous essayez de créer une liste distincte de tous les « genres » dans votre liste.

En supposant une structure de données qui ressemble un peu à ceci:

<root> 
<nodes> 
    <node> 
     <data> 
      <genres> 
       <value>One</value> 
       <value>Two</value> 
       <value>Two</value> 
       <value>Three</value> 
       <value>Two</value> 
      </genres> 
     </data> 
    </node> 
</nodes> 
</root> 

Et une feuille de style qui ressemble un peu à ceci:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:key name="genres" match="value" use="."/> 

<xsl:template match="/"> 
    <div> 
     <xsl:for-each select="/root/nodes/node/data/genres/value"> 
      <xsl:if test="generate-id(.) = generate-id(key('genres', .)[1])"> 
       <a href="#"><xsl:value-of select="."/></a> 
      </xsl:if> 
     </xsl:for-each> 
    </div> 
</xsl:template> 
</xsl:stylesheet> 

Ensuite, vous finirez avec quelque chose comme ceci:

<div> 
<a href="#">One</a> 
<a href="#">Two</a> 
<a href="#">Three</a> 
</div> 

Il s'agit d'une technique XSLT 1.0 assez standard. Il utilise des clés (décrites ici: http://www.xml.com/pub/a/2002/02/06/key-lookups.html) pour créer une sorte d'index de toutes les entrées/root/nodes/node/data/genres/valeurs. Ensuite, il passe en revue toutes les entrées, mais imprime seulement le premier de chaque type. Le résultat final est que chaque valeur ne sera sortie qu'une seule fois.