iTerm AppleScript pour écrire dans deux volets de verticle séparés

Question

Je suis en train d'écrire un AppleScript: - ouvre une nouvelle fenêtre - change répertoire - divise les volets verticalement dans ce même répertoire - écrit le texte dans le volet gauche - écrit le texte dans le panneau de droite

et, si possible, exécute les deux volets simultanément.

Le plus proche que je puisse obtenir est de faire des fenêtres similaires mais en ouvrant deux fenêtres séparées. comme ceci:

tell application "iTerm" 
     set myterm to create window with default profile 
     tell myterm 
      activate current session 
      launch session "Default Session" 
      tell the current session 
      write text "cd ~/Desktop" 
      write text "xcodebuild clean -workspace -scheme WelcomeScreenTests -sdk iphonesimulator -destination 'platform=iOS Simulator,id=476E9E8C-8248-4EF6-8054-67900D603E83' test | xcpretty" 
      end tell 
    end tell 
    set myterm to create window with default profile 
    tell myterm 
     activate current session 
     launch session "Default Session" 
     tell the current session 
      write text "cd ~/Desktop" 
      write text "xcodebuild clean -workspace -scheme WelcomeScreenTests2 -sdk iphonesimulator -destination 'platform=iOS Simulator,id=F3DEA448-147B-4DDB-AD83-16D18BA1A87F' test | xcpretty" 
     end tell 
    end tell 

Toute aide serait un grand merci

Answer 1

Il est possible.

tell application "iTerm" 
    set myterm to create window with default profile 
    tell myterm 
     activate current session 
     launch session "Default Session" 
     tell the current session 
      write text "cd ~/Desktop" 

      -- use 'without newline' to write without executing the command 
      write text "xcodebuild clean -workspace -scheme WelcomeScreenTests -sdk iphonesimulator -destination 'platform=iOS Simulator,id=476E9E8C-8248-4EF6-8054-67900D603E83' test | xcpretty" without newline 
      tell (split vertically with same profile) 
       write text "cd ~/Desktop" 

       -- use 'without newline' to write without executing the command 
       write text "xcodebuild clean -workspace -scheme WelcomeScreenTests2 -sdk iphonesimulator -destination 'platform=iOS Simulator,id=F3DEA448-147B-4DDB-AD83-16D18BA1A87F' test | xcpretty" without newline 
      end tell 
     end tell 
     write (sessions of current tab) text linefeed -- append newline to the last line of each session to executes both panes simultaneously. 
    end tell 
end tell