Perl: Suppression d'éléments de tableau et redimensionnement du tableau

Question

J'essaie de filtrer un tableau de termes en utilisant un autre tableau en Perl. J'ai Perl 5.18.2 sur OS X, mais le comportement est le même si je use 5.010. Voici ma configuration de base:

#!/usr/bin/perl 
#use strict; 
my @terms = ('alpha','beta test','gamma','delta quadrant','epsilon', 
      'zeta','eta','theta chi','one iota','kappa'); 
my @filters = ('beta','gamma','epsilon','iota'); 
foreach $filter (@filters) { 
    for my $ind (0 .. $#terms) { 
     if (grep { /$filter/ } $terms[$ind]) { 
      splice @terms,$ind,1; 
     } 
    } 
} 

Cela fonctionne pour tirer les lignes qui correspondent aux différents termes de recherche, mais la longueur du tableau ne change pas. Si j'écris sur le tableau @terms résultant, je reçois:

[alpha] 
[delta quadrant] 
[zeta] 
[eta] 
[theta chi] 
[kappa] 
[] 
[] 
[] 
[] 

Comme vous pouvez attendre de cela, l'impression scalar(@terms) obtient un résultat de 10.

Ce que je veux est un tableau résultant de longueur 6, sans les quatre éléments vides à la fin. Comment puis-je obtenir ce résultat? Et pourquoi le tableau ne rétrécit-il pas, étant donné que le perldoc page about splice dit: «Le tableau croît ou se rétrécit si nécessaire.»?

(Je ne parle pas couramment Perl, donc si vous pensez "Pourquoi ne pas juste ...?", C'est presque certainement parce que je ne le sais pas ou je ne l'ai pas compris quand j'en ai entendu parler.)

Answer 1

Vous pouvez toujours régénérer le tableau moins les choses que vous ne voulez pas. grep agit comme un filtre vous permettant de décider quels éléments vous voulez et que vous ne faites:

#!/usr/bin/perl 

use strict; 

my @terms = ('alpha','beta test','gamma','delta quadrant','epsilon', 
      'zeta','eta','theta chi','one iota','kappa'); 
my @filters = ('beta','gamma','epsilon','iota'); 

my %filter_exclusion = map { $_ => 1 } @filters; 

my @filtered = grep { !$filter_exclusion{$_} } @terms; 

print join(',', @filtered) . "\n"; 

Il est assez facile si vous avez une structure simple comme %filter_exclusion à portée de main.

Mise à jour: Si vous souhaitez autoriser correspond substring arbitraire:

my $filter_exclusion = join '|', map quotemeta, @filters; 

my @filtered = grep { !/$filter_exclusion/ } @terms; 

Answer 2

Pour voir ce qui se passe, imprimer le contenu du tableau à chaque étape: Lorsque vous Splice le tableau, il se rétrécit, mais votre boucle itère sur 0 .. $ # termes, donc à la fin de la boucle, $ ind pointera derrière la fin du tableau. Lorsque vous utilisez grep { ... } $array[ $too_large ], Perl doit aliaser l'élément inexistant à $_ à l'intérieur du bloc grep, de sorte qu'il crée un élément undef dans le tableau.

#!/usr/bin/perl 
use warnings; 
use strict; 
use feature qw{ say }; 

my @terms = ('alpha', 'beta test', 'gamma', 'delta quadrant', 'epsilon', 
      'zeta', 'eta', 'theta chi', 'one iota', 'kappa'); 
my @filters = qw(beta gamma epsilon iota); 

for my $filter (@filters) { 
    say $filter; 
    for my $ind (0 .. $#terms) { 
     if (grep { do { 
      no warnings 'uninitialized'; 
      /$filter/ 
     } } $terms[$ind] 
     ) { 
      splice @terms, $ind, 1; 
     } 
     say "\t$ind\t", join ' ', map $_ || '-', @terms; 
    } 
} 

Si vous avez utilisé $terms[$ind] =~ /$filter/ au lieu de grep, vous souhaitez toujours obtenir des avertissements non initialisées, mais comme il n'y a pas besoin d'un alias l'élément, il ne sera pas créé.