Voir les sites qui utilisent les adresses IP dans IIS 7

Question

Existe-t-il un moyen de répertorier rapidement les sites sur quelle adresse IP dans IIS 7? Si je me souviens bien, vous pourriez trier une vue des domaines par IP dans IIS 6, ce qui m'a été d'une grande aide pour voir quelles adresses IP j'avais à ma disposition.

Answer 1

Vous pouvez essayer ce script:

MachineName = "localhost" 
IIsObjectPath = "IIS://" & MachineName & "/w3svc" 

WScript.Echo "Checking : " & IISObjectPath 

Set IIsObject = GetObject(IIsObjectPath) 
for each obj in IISObject 
    if (Obj.Class = "IIsWebServer") then 
     BindingPath = IIsObjectPath & "/" & Obj.Name 

     Set IIsObjectIP = GetObject(BindingPath) 
     wScript.Echo BindingPath & " - " & IISObjectIP.ServerComment 

     ValueList = IISObjectIP.Get("ServerBindings") 
       ValueString = "" 
     For ValueIndex = 0 To UBound(ValueList) 
      value = ValueList(ValueIndex) 
      Values = split(value, ":") 
      IP = values(0) 
      if (IP = "") then 
       IP = "(All Unassigned)" 
      end if 
      TCP = values(1) 
      if (TCP = "") then 
       TCP = "80" 
      end if 
      HostHeader = values(2) 

      if (HostHeader <> "") then 
        wScript.Echo " IP = " & IP & " TCP/IP Port = " & TCP & ", HostHeader = " & HostHeader 
      else 
        wScript.Echo " IP = " & IP & " TCP/IP Port = " & TCP 
      end if 
       Next          
     wScript.Echo "" 
     set IISObjectIP = Nothing 
    end if 
next 
set IISObject = Nothing 

(source de www.iisfaq.com)

Answer 2

Jetez un oeil à APPCMD.

Par exemple, pour répertorier tous les sites sur la machine, utilisez cette commande en ligne:

%systemroot%\system32\inetsrv\APPCMD list sites