GNU linker ARM - pourquoi mes sections se chevauchent?

Question

Je dois ajouter un petit tas pour utiliser les fonctions de bibliothèque standard sur un microcontrôleur ARM TM4C (_sbrk nécessite le symbole end).

Ceci est mon script éditeur de liens (est venu avec une démonstration de microcontrôleur):

/* Entry Point */ 
ENTRY(Reset_Handler) 

HEAP_SIZE = 1024; 

MEMORY 
{ 
    FLASH (rx) : ORIGIN = 0x00000000, LENGTH = 0x00100000 
    SRAM (rwx) : ORIGIN = 0x20000000, LENGTH = 0x00040000 
} 

SECTIONS 
{ 
    .text : 
    { 
     _text = .; 
     KEEP(*(.isr_vector)) 
     *(.text*) 
     *(.rodata*) 
     _etext = .; 
    } > FLASH 

    .data : AT(ADDR(.text) + SIZEOF(.text)) 
    { 
     _data = .; 
     _ldata = LOADADDR (.data); 
     *(vtable) 
     *(.data*) 
     _edata = .; 
    } > SRAM 

    .bss : 
    { 
     _bss = .; 
     *(.bss*) 
     *(COMMON) 
     _ebss = .; 
    } > SRAM 

    .heap : AT(ADDR(.bss) + SIZEOF(.bss)) 
    { 
     . = ALIGN(8); 
     __end__ = .; 
     PROVIDE(end = .); 
     __HeapBase = .; 
     . += HEAP_SIZE; 
     __HeapLimit = .; 
    } > SRAM 
} 

Je ne .heap ajouté après .bss analogiquement à .data/.text mais je reçois lien erreur:

ld: section .init loaded at [000126b4,000126bf] overlaps section .data loaded at [000126b4,00012f8f] 
collect2: error: ld returned 1 exit status 

Cela se produit également lorsque je supprime AT(ADDR(.bss) + SIZEOF(.bss)). Lorsque je supprime .heap et appelle les fonctions libc tout compile et lie, le binaire de sortie s'exécute correctement.

Comment dois-je ajuster le script pour placer correctement le tas après bss?

Answer 1

Il s'est avéré que mon tas et bss étaient corrects, mais lors de la liaison des fonctions de bibliothèque standard de nouvelles sections appelées .init et .fini sont ajoutées - elles sont entrées en collision avec .data. Ceci est mon script linker corrigé:

/* Entry Point */ 
ENTRY(Reset_Handler) 

HEAP_SIZE = 1024; 

MEMORY 
{ 
    FLASH (rx) : ORIGIN = 0x00000000, LENGTH = 0x00100000 
    SRAM (rwx) : ORIGIN = 0x20000000, LENGTH = 0x00040000 
} 

SECTIONS 
{ 
    .text : 
    { 
     _text = .; 
     KEEP(*(.isr_vector)) 
     *(.text*) 
     *(.rodata*) 
     KEEP (*(.init)) 
     KEEP (*(.fini)) 
     _etext = .; 
    } > FLASH 

    .ARM.extab : 
    { 
     *(.ARM.extab* .gnu.linkonce.armextab.*) 
    } > FLASH 

    .ARM : 
    { 
     __exidx_start = .; 
     *(.ARM.exidx*) 
     __exidx_end = .; 
    } > FLASH 

    __end_code = .; 

    .data : AT(__end_code) 
    { 
     _data = .; 
     _ldata = LOADADDR (.data); 
     *(vtable) 
     *(.data*) 
     _edata = .; 
    } > SRAM 

    .bss : 
    { 
     _bss = .; 
     *(.bss*) 
     *(COMMON) 
     _ebss = .; 
    } > SRAM 

    .heap : AT(_ebss) 
    { 
     . = ALIGN(8); 
     __end__ = .; 
     PROVIDE(end = .); 
     __HeapBase = .; 
     . += HEAP_SIZE; 
     __HeapLimit = .; 
    } > SRAM 
} 

I ajouté des lignes KEEP (*(.init)), KEEP (*(.fini)) et .ARM sections (à partir d'un autre script de liaison MCU). Maintenant tout relie et fonctionne bien.