Comment analyser JSON dans une raquette?

Question

Je n'arrive pas à comprendre le {documentation}, il n'y a pas vraiment d'exemples d'analyse de données JSON simples, donc je me demandais si quelqu'un pouvait me donner quelques exemples pour commencer.

Answer 1

Voici un exemple très simple:

(require json) 
(define x (string->jsexpr "{\"foo\": \"bar\", \"bar\": \"baz\"}")) 
(for (((key val) (in-hash x))) 
    (printf "~a = ~a~%" key val)) 

Voilà comment vous pouvez l'utiliser avec une API JSON:

(require net/http-client json) 
(define-values (status header response) 
    (http-sendrecv "httpbin.org" "/ip" #:ssl? 'tls)) 
(define data (read-json response)) 
(printf "My IP address is ~a~%" (hash-ref data 'origin)) 

À la demande de l'OP, voici comment vous pouvez créer une valeur JSON à partir d'un type de structure:

(require json) 
(struct person (first-name last-name age country)) 
(define (person->jsexpr p) 
    (hasheq 'first-name (person-first-name p) 
      'last-name (person-last-name p) 
      'age (person-age p) 
      'country (person-country p))) 
(define cky (person "Chris" "Jester-Young" 33 "New Zealand")) 
(jsexpr->string (person->jsexpr cky))