Arrêtez SAS d'essayer de résoudre et de référencer dans une macro macro

Question

Je cours un processus qui répertorie les tâches sur lesquelles je veux vérifier la date de modification. Je liste les travaux dans un ensemble de données, puis les transmets aux variables de macro avec un nombre.

par exemple.

Data List_Prep; 
Format Folder 
     Code $100.; 
Folder = 'C:\FilePath\Job ABC'; Code = '01 Job Name.sas'; Output; 
Folder = 'C:\FilePath\Job X&Y'; Code = '01 Another Job.sas'; Output; 
Run; 
%Macro List_Check(); 
Data List; 
    Set List_Prep; 
    Job + 1; 

    Call Symput (Cats("Folder", Job), Strip(Folder)); 
    Call Symput (Cats("Code", Job), Strip(Code)); 

Run; 
%Put Folder1 = &Folder1; 
%Put Folder2 = &Folder2; 
%MEnd; 
%List_Check; 

Il imprime l'instruction% Mettez bien pour foler 1, mais le dossier 2 ne fonctionne pas correctement.

Folder1 = C:\FilePath\Job ABC 
WARNING: Apparent symbolic reference Y not resolved. 
Folder2 = C:\FilePath\Job X&Y 

Quand je vais alors dans une boucle pour vérifier les ensembles de données, encore une fois, ça marche, donc cherche Dossier1, Code1 etc, mais je reçois toujours les avertissements.

Comment puis-je arrêter ces avertissements? J'ai essayé% Str ("&") à la place, mais toujours le problème.

Answer 1

Vous pouvez empêcher SAS de tenter de résoudre l'esperluette de la valeur en utilisant la fonction %superq

%put Folder2 = %superq(Folder2); 

Answer 2

La fonction macro %superq() est une excellente façon de masquer les déclencheurs macro qui sont déjà dans une variable macro. Vous pouvez soit n'oubliez pas de citer les valeurs lors de leur utilisation,

%put Folder1 = %superq(Folder1) ; 

ou vous pouvez ajuster votre processus pour les citer juste après leur création.

data List_Prep; 
    length Folder Code $100; 
    Folder = 'C:\FilePath\Job ABC'; Code = '01 Job Name.sas'; Output; 
    Folder = 'C:\FilePath\Job X&Y'; Code = '01 Another Job.sas'; Output; 
run; 
data List; 
    set List_Prep; 
    Job + 1; 
    length dummy $200 ; 
    call symputx(cats("Folder", Job), Folder); 
    dummy = resolve(catx(' ','%let',cats("Folder", Job),'=%superq(',cats("Folder", Job),');')); 
    call symputx(cats("Code", Job), Code); 
    dummy = resolve(catx(' ','%let',cats("Code", Job),'=%superq(',cats("Code", Job),');')); 
    drop dummy; 
run; 

P.S. N'utilisez pas FORMAT pour définir des variables. Utilisez des instructions telles que LENGTH ou ATTRIB conçues pour définir des variables. FORMAT est pour attacher des formats à la variable, pas pour les définir. La seule raison pour laquelle FORMAT a fonctionné est qu'il a eu l'effet secondaire de SAS définissant le type et la longueur de la variable pour correspondre au format auquel vous l'avez attaché car c'était le premier endroit où vous avez référencé la variable dans l'étape de données.