xsl trouver tout le nœud qui ont un nom alors comme la valeur d'un autre noeud

Question

Comment puis-je trouver avec Xsl tout le nœud qui ont un nom alors comme la valeur d'un autre noeud comme ceux-ci:

<root> 
    <data1> 
     <subdata1> 
     ... 
     <selectThese></selectThese> 
     ... 
     </subdata1> 

    </data1> 
    <nodesetFind> 
     <node1>selectThese</node1> 
    </nodesetFind> 
    </root> 

le résultat: <selectThese></selectThese>

Answer 1

utilisation:

/*/data1//*[name() = /*/nodesetFind/*] 

démontrée dans un XS LT transformation:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:template match="/"> 
    <xsl:copy-of select="/*/data1//*[name() = /*/nodesetFind/*]"/> 
</xsl:template> 
</xsl:stylesheet> 

lorsque cette transformation est appliquée sur le document XML fourni:

<root> 
    <data1> 
     <subdata1> 
     ... 
     <selectThese></selectThese> 
     ... 
     </subdata1> 

    </data1> 
    <nodesetFind> 
     <node1>selectThese</node1> 
    </nodesetFind> 
    </root> 

le résultat recherché, correct est produit:

<selectThese></selectThese> 

Answer 2

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:template match="/"> 
     <xsl:variable name="find" select="//nodesetFind/node1" /> 
     <root> 
      <xsl:for-each select="//*[name()=$find]"> 
       <xsl:copy-of select="." /> 
      </xsl:for-each> 
     </root> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 3

Une autre façon, cette feuille de style:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:key name="kDataByName" match="*[ancestor::data1]" use="name()"/> 
    <xsl:template match="/"> 
     <xsl:copy-of select="key('kDataByName',/root/nodesetFind/node1)"/> 
    </xsl:template> 
</xsl:stylesheet> 

Sortie:

<selectThese></selectThese> 

Remarque: Ceci est la solution XSLT uniquement (la réponse de Dimitre est XPath générale, puis XSLT) parce que l'utilisation de fn:key. Donc, vous devez déclarer la clé pour utiliser cette expression pour sélectionner les nœuds que vous voulez:

key('kDataByName',/root/nodesetFind/node1)