Pourquoi cette fonction est-elle non déterministe?

Question

Pourquoi SQL Server pense-t-il que cette fonction est non déterministe?

CREATE FUNCTION [Util].[BuildStreetFullName] 
(
    @StreetNumber VARCHAR(20), 
    @StreetDir VARCHAR(2), 
    @StreetName VARCHAR(50) , 
    @StreetType VARCHAR(4) , 
    @StreetPostDir VARCHAR(2) 
) 
RETURNS VarChar(100) 
AS 
BEGIN 
    SET @StreetNumber = NULLIF(Util.Trim(@StreetNumber ), ''); 
    SET @StreetDir  = NULLIF(Util.Trim(@StreetDir  ), ''); 
    SET @StreetName  = NULLIF(Util.Trim(@StreetName ), ''); 
    SET @StreetType  = NULLIF(Util.Trim(@StreetType ), ''); 
    SET @StreetPostDir = NULLIF(Util.Trim(@StreetPostDir ), ''); 

    DECLARE @Result VarChar(100) = @StreetNumber; 

    IF @StreetDir IS NOT NULL BEGIN 
     IF @Result IS NOT NULL 
      SET @Result = @Result + ' ' + @StreetDir; 
     ELSE 
      SET @Result = @StreetDir; 
    END 

    IF @StreetName IS NOT NULL BEGIN 
     IF @Result IS NOT NULL 
      SET @Result = @Result + ' ' + @StreetName; 
     ELSE 
      SET @Result = @StreetName; 
    END 


    IF @StreetType IS NOT NULL BEGIN 
     IF @Result IS NOT NULL 
      SET @Result = @Result + ' ' + @StreetType; 
     ELSE 
      SET @Result = @StreetType; 
    END 

    IF @StreetPostDir IS NOT NULL BEGIN 
     IF @Result IS NOT NULL 
      SET @Result = @Result + ' ' + @StreetPostDir; 
     ELSE 
      SET @Result = @StreetPostDir; 
    END 

    RETURN NULLIF(@Result, ''); 
END 

CREATE FUNCTION [Util].[Trim] 
(
    @value nVarChar(max) 
) 
RETURNS nVarChar(max) 
AS 
BEGIN 
    RETURN LTrim(RTrim(@value)) 
END 

Answer 1

1) Vous pouvez créer à la fois la fonction WITH SCHEMABINDING:

ALTER FUNCTION dbo.[Trim] 
(
    @value nVarChar(max) 
) 
RETURNS nVarChar(max) 
WITH SCHEMABINDING 
AS 
... 

et

ALTER FUNCTION dbo.[BuildStreetFullName] 
(
    @StreetNumber VARCHAR(20), 
    @StreetDir VARCHAR(2), 
    @StreetName VARCHAR(50) , 
    @StreetType VARCHAR(4) , 
    @StreetPostDir VARCHAR(2) 
) 
RETURNS VarChar(100) 
WITH SCHEMABINDING 
AS 
... 

Cela forcera SQL Server pour vérifier si ces fonctions sont déterministes ou non.

SELECT OBJECTPROPERTY(OBJECT_ID(N'dbo.[BuildStreetFullName]') , 'IsDeterministic') AS IsDeterministic 

Sortie:

IsDeterministic 
--------------- 
1 

2) S'il vous plaît ne pas utiliser != NULL opérateur pour vérifier NOT NULL. Utilisez IS NOT NULL. À ce moment ANSI_NULLS OFF est obsolète et une future version de SQL Server autorisera seulement ANSI_NULLS ON.

3) Les fonctions scalaires peuvent être un cauchemar du point de vue de la performance. Je voudrais réécrire ces fonctions comme inline table valued functions.