Fichiers batch: comment lire un fichier?

Question

Comment lire un fichier (texte ou binaire) à partir d'un fichier batch? Il y a un moyen de le lire en mode binaire ou en mode texte?

Answer 1

Vous pouvez utiliser la commande pour:

FOR /F "eol=; tokens=2,3* delims=, " %i in (myfile.txt) do @echo %i %j %k 

Type de

for /? 

à l'invite de commande. En outre, vous pouvez parse ini files!

Answer 2

Sous cmd.exe style NT, vous pouvez boucler à travers les lignes d'un fichier texte avec

FOR /F %i IN (file.txt) DO @echo %i 

Tapez « l'aide » à l'invite de commande pour plus d'informations. (Ne sais pas si cela fonctionne dans tout ce "DOS" vous utilisez)

Answer 3

Le FOR-LOOP fonctionne généralement, mais il y a quelques problèmes. Le FOR n'accepte pas les lignes vides et les lignes de plus de ~ 8190 sont problématiques. L'expansion fonctionne seulement fiable, si l'expansion retardée est désactivée.

La détection de CR/LF versus simple LF semble également un peu compliquée.
Les caractères NUL sont également problématiques, car une boucle FOR annule immédiatement la lecture.

Direct La lecture binaire semble donc presque impossible.

Le problème avec les lignes vides peut être résolu avec une astuce. Préfixe chaque ligne avec un numéro de ligne, en utilisant la commande findstr, et après la lecture, supprime le préfixe.

@echo off 
SETLOCAL DisableDelayedExpansion 
FOR /F "usebackq delims=" %%a in (`"findstr /n ^^ t.txt"`) do (
    set "var=%%a" 
    SETLOCAL EnableDelayedExpansion 
    set "var=!var:*:=!" 
    echo(!var! 
    ENDLOCAL 
) 

Basculement entre activer et désactivé l'expansion retardée neccessaire pour le coffre-fort de travailler avec des chaînes, comme ! ou ^^^xy!z.
C'est parce que la ligne set "var=%%a" n'est sûre qu'avec DisabledDelayedExpansion, sinon les points d'exclamation sont supprimés et les carets sont utilisés comme caractères d'échappement (secondaires) et ils sont également supprimés.
Mais l'utilisation de la variable var n'est sûre qu'avec EnabledDelayedExpansion, car même un call %%var%% échouera avec un contenu tel que "&"&.

EDIT: Ajout défini/variante p
Il y a une deuxième façon de lire un fichier avec set /p, les seuls inconvénients sont qu'il est limité à ~ 1024 caractères par ligne et supprime les caractères de contrôle à la fin de la ligne .
Mais l'avantage est, vous ne l'avez pas besoin du basculement retardé et il est plus facile à stocker des valeurs dans les variables

@echo off 
setlocal EnableDelayedExpansion 
set "file=%~1" 

for /f "delims=" %%n in ('find /c /v "" %file%') do set "len=%%n" 
set "len=!len:*: =!" 

<%file% (
    for /l %%l in (1 1 !len!) do (
    set "line=" 
    set /p "line=" 
    echo(!line! 
) 
) 

Pour lire « binaire » dans une représentation hexagonale
Vous pouvez regarder SO: converting a binary file to HEX representation using batch file

Answer 4

si vous voulez juste pour l'afficher sur cmd, vous pouvez utiliser ceci:

cat myfile.txt 

Answer 5

bien al theres ot de différentes façons, mais si vous voulez seulement afficher le texte et entreposez pas partout, vous utilisez juste: findstr /v "randomtextthatnoonewilluse" filename.txt

Answer 6

Un moyen très facile de le faire est d'utiliser la commande suivante:

set /p mytextfile=< %pathtotextfile%\textfile.txt 
echo %mytextfile% 

Cette volonté affiche uniquement la première ligne de texte dans un fichier texte. L'autre façon, vous pouvez le faire est d'utiliser la commande suivante:

type %pathtotextfile%\textfile.txt 

Cela mettra toutes les données dans le fichier texte à l'écran. J'espère que cela t'aides!