Comment utiliser XSLT pour créer des valeurs distinctes

Question

je XML comme ceci:

<items> 
    <item> 
    <products> 
     <product>laptop</product> 
     <product>charger</product> 
    </products> 
    </item> 
    <item> 
    <products> 
     <product>laptop</product> 
     <product>headphones</product> 
    </products> 
    </item> 
</items> 

Je veux à la sortie comme

 
laptop 
charger 
headphones 

Je tentais d'utiliser distinct-values() mais je suppose im faire quelque chose de mal . Quelqu'un peut-il me dire comment y parvenir en utilisant distinct-values()? Merci.

<xsl:template match="/">    
    <xsl:for-each select="//products/product/text()"> 
    <li> 
     <xsl:value-of select="distinct-values(.)"/> 
    </li>    
    </xsl:for-each> 
</xsl:template> 

mais sa me donner une sortie comme ceci:

<li>laptop</li> 
<li>charger</li> 
<li>laptop></li> 
<li>headphones</li> 

Answer 1

Une solution XSLT 1,0 qui utilise key et la fonction generate-id() pour obtenir des valeurs distinctes:

<?xml version="1.0" encoding="UTF-8"?> 
    <xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" encoding="UTF-8" indent="yes"/> 

<xsl:key name="product" match="/items/item/products/product/text()" use="." /> 

<xsl:template match="/"> 

    <xsl:for-each select="/items/item/products/product/text()[generate-id() 
             = generate-id(key('product',.)[1])]"> 
    <li> 
     <xsl:value-of select="."/> 
    </li> 
    </xsl:for-each> 

</xsl:template> 

</xsl:stylesheet> 

Answer 2

distinct-values(//product/text())

Answer 3

Vous ne voulez pas "sortie (valeurs distinctes)", mais plutôt « for-each (distinct- valeurs) ":

<xsl:template match="/">    
    <xsl:for-each select="distinct-values(/items/item/products/product/text())"> 
    <li> 
     <xsl:value-of select="."/> 
    </li> 
    </xsl:for-each> 
</xsl:template> 

Answer 4

est ici une solution XSLT 1.0 que je l'ai utilisé dans le passé, je pense qu'il est plus succinct (et lisible) que d'utiliser la fonction generate-id().

<xsl:template match="/">   
    <ul> 
     <xsl:for-each select="//products/product[not(.=preceding::*)]"> 
     <li> 
      <xsl:value-of select="."/> 
     </li> 
     </xsl:for-each>    
    </ul> 
    </xsl:template> 

Retours:

<ul xmlns="http://www.w3.org/1999/xhtml"> 
    <li>laptop</li> 
    <li>charger</li> 
    <li>headphones</li> 
</ul> 

Answer 5

Je suis venu à ce problème tout en travaillant avec un rendu XSL Sitecore. L'approche qui a utilisé key() et l'approche qui a utilisé l'axe précédent a été très lente. J'ai fini par utiliser une méthode similaire à key() mais cela n'a pas nécessité d'utiliser key(). Il effectue très rapidement.

<xsl:variable name="prods" select="items/item/products/product" /> 
<xsl:for-each select="$prods"> 
    <xsl:if test="generate-id() = generate-id($prods[. = current()][1])"> 
    <xsl:value-of select="." /> 
    <br /> 
    </xsl:if> 
</xsl:for-each>