Turbo Pascal: vérifier si la chaîne contient des nombres

Question

Comme il est dit dans le titre Im ayant du mal à trouver une solution sur la façon de vérifier si une chaîne PW contient un nombre ou non. Comment puis-je vérifier dans TP si la chaîne PW contient un chiffre?

repeat 
     writeln; 
     writeln('Ok, please enter your future password.'); 
     writeln('Attention: The Text can only be decoded with the same PW'); 
     readln(PW); 
     pwLength:= Length(PW); 
     error:=0; 
      for i:= 1 to Length(PW) do begin 
      if Input[i] in ['0'..'9'] then begin 
      error:=1; 
      end; 
      end; 

      if Length(PW)=0 then 
      begin 
      error:=1; 
      end; 

      if Length(PW)>25 then 
      begin 
      error:=1; 
      end; 

     if error=1 then 
     begin 
     writeln('ERROR: Your PW has to contain at least 1character, no numbers and has to be under 25characters long.'); 
     readln; 
     clrscr; 
     end; 

     until error=0; 

Answer 1

Voici comment j'écrire votre code:

var 
    PW : String; 
    Error : Integer; 

const 
    PWIsOk = 0; 
    PWIsBlank = 1; 
    PWTooLong = 2; 
    PWContainsDigit = 3; 

procedure CheckPassword; 
var 
    i : Integer; 
begin 

    writeln; 
    writeln('Ok, please enter your future password.'); 
    writeln('Attention: The Text can only be decoded with the same PW'); 
    writeln('Your password must be between 1 and 25 characters long and contain no digits.'); 

    repeat 
    error := PWIsOk; 
    readln(PW); 

    if Length(PW) = 0 then 
     Error := PWIsBlank; 

    if Error = PWIsOk then begin 
     if Length(PW) > 25 then 
     Error := PWTooLong; 
     if Error = 0 then begin 
     for i := 1 to Length(PW) do begin 
      if (PW[i] in ['0'..'9']) then begin 
      Error := PWContainsDigit; 
      Break; 
      end; 
     end; 
     end; 
    end; 

    case Error of 
     PWIsOK : writeln('Password is ok.'); 
     PWIsBlank : writeln('Password cannot be blank.'); 
     PWTooLong : writeln('Password is too long.'); 
     PWContainsDigit : writeln('Password should not contain a digit'); 
    end; { case} 
    until Error = PWIsOk; 
    writeln('Done'); 
end; 

Ce sont quelques-unes des choses à noter:

• Ne pas utiliser la même valeur de code d'erreur pour représenter différents types d'erreur. L'utilisation de la même valeur pour différentes erreurs rend plus difficile le débogage de votre code, car vous ne pouvez pas dire quel test a donné Error la valeur 1.

• Définir des constantes pour représenter les différents types d'erreur. De cette façon, les lecteurs ne pas se demander « Qu'est-ce que 3 moyenne » dans if error = 3 ...

• Une fois que vous avez détecté un caractère chiffre du mot de passe, il n'y a pas de point après examen des caractères, d'où l'Break dans mon for boucle.

• Si j'étais un utilisateur je serais ennuyé de ne pas être dit quelles sont les règles jusqu'à ce que le programme me dise que j'ai fait quelque chose de mal. Dites l'utilisation d'avance quelles sont les règles.

• En fait, il serait préférable d'inclure un Unclassified constant supplémentaire d'une valeur de par exemple, -1, et commencer à chaque itération de la boucle en affectant Error à elle et, dans les étapes suivantes, essai pour Error = Unclassified plutôt que PWIsOk.

• Une instruction case est un moyen propre et facilement maintenable de sélectionner l'un des nombreux chemins d'exécution mutuellement exclusifs basés sur une valeur ordinale.