Coloration des points spécifiques avec une couleur différente dans Mathematica

Question

La sortie de la commande Mathematica

ListPointPlot3D[ 
    Join @@ Table[{x, y, 0}, {x, -6, 6, 1}, {y, -6, 6, 1}], 
    PlotStyle -> PointSize[0.02]] 

est l'image suivante.

Je veux colorer les points (0,0) et (1,2) avec la couleur rouge. Comment puis-je modifier la commande ci-dessus pour cela?

Answer 1

Une façon très simple et direct serait:

list = Join @@ Table[{x, y, 0}, {x, -6, 6, 1}, {y, -6, 6, 1}]; 
pts = {{0, 0, 0}, {1, 2, 0}}; 

ListPointPlot3D[{Complement[list, pts], pts}, 
PlotStyle -> PointSize[0.02]] 

Bien sûr, je l'ai laissé sans préciser explicitement les couleurs, car la couleur suivante par défaut est rouge. Cependant, si vous voulez spécifier le vôtre, vous pouvez le modifier un peu plus comme:

ListPointPlot3D[{Complement[list, pts], pts}, 
PlotStyle -> {{Green, #}, {Blue, #}} &@PointSize[0.02]] 

Answer 2

yoda montre une méthode fine. Parfois, cependant, il est plus facile de travailler directement avec des primitives graphiques. Voici un exemple de cela, bien que dans ce cas je choisirais la méthode de Yoda.

Graphics3D[{ 
    PointSize[0.02], 
    Point /@ Join @@ Table[{x, y, 0}, {x, -6, 6, 1}, {y, -6, 6, 1}] /. 
    x : _@{1, 2, 0} | _@{0, 0, 0} :> Style[x, Red] 
}] 

Answer 3

On pourrait utiliser l'option ColorFunction à ListPointPlot3D:

color[0, 0, _] = Red; 
color[1, 2, _] = Red; 
color[_, _, _] = Blue; 

ListPointPlot3D[ 
    Join @@ Table[{x, y, 0}, {x, -6, 6, 1}, {y, -6, 6, 1}], 
    PlotStyle -> PointSize[0.02], 
    ColorFunction -> color, ColorFunctionScaling -> False] 

Il est important d'inclure l'option ColorFunctionScaling -> False car sinon le x, y et z les coordonnées passées à la fonction de couleur seront normalisées dans la plage à .

ColorFunction nous permet également de définir la coloration de point en utilisant des calculs arbitraires, par exemple:

color2[x_, y_, _] /; x^2 + y^2 <= 9 = Red; 
color2[x_, y_, _] /; Abs[x] == Abs[y] = Green; 
color2[_, _, _] = Blue; 

ListPointPlot3D[ 
    Join @@ Table[{x, y, 0}, {x, -6, 6, 1}, {y, -6, 6, 1}], 
    PlotStyle -> PointSize[0.02], 
    ColorFunction -> color2, ColorFunctionScaling -> False]