Comment obtenir la date d'hier en utilisant localtime?

Question

Comment est-ce que je bidouille ceci pour obtenir la date d'hier en utilisant localtime?

use strict; 

sub spGetCurrentDateTime; 
print spGetCurrentDateTime; 

sub spGetCurrentDateTime { 
my ($sec, $min, $hour, $mday, $mon, $year) = localtime(); 
my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec); 
my $currentDateTime = sprintf "%s %02d %4d", $abbr[$mon], $mday, $year+1900; #Returns => 'Aug 17 2010' 
return $currentDateTime; 
} 

~

Answer 1

Le problème DST peut être contourné en prenant 3600s à partir de midi aujourd'hui au lieu de l'heure actuelle:

#!/usr/bin/perl 
use strict; 
use warnings; 
use Time::Local; 

sub spGetYesterdaysDate; 
print spGetYesterdaysDate; 

sub spGetYesterdaysDate { 
my ($sec, $min, $hour, $mday, $mon, $year) = localtime(); 
my $yesterday_midday=timelocal(0,0,12,$mday,$mon,$year) - 24*60*60; 
($sec, $min, $hour, $mday, $mon, $year) = localtime($yesterday_midday); 
my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec); 
my $YesterdaysDate = sprintf "%s %02d %4d", $abbr[$mon], $mday, $year+1900; 
return $YesterdaysDate; 
} 

À la lumière de la « non spécifié » comportement documenté de la solution strftime proposée par Chas, cette approche pourrait être meilleure si vous n'êtes pas en mesure de tester les résultats attendus mais non garantis sur plusieurs plates-formes.

Answer 2

localtime(time() - 24*60*60) 

Answer 3

utilisation Time::Piece.

use strict; 
use warnings; 
use 5.010; 

# These are core modules in Perl 5.10 and newer 
use Time::Piece; 
use Time::Seconds; 

my $yesterday = localtime() - ONE_DAY; 
say $yesterday->strftime('%b %d %Y'); 

Notez que cela peut mal tourner dans certains cas limites, tels que le début de l'heure d'été. La version suivante ne se comporte correctement dans de tels cas:

use strict; 
use warnings; 
use 5.010; 

# These are core modules in Perl 5.10 and newer 
use Time::Piece; 
use Time::Seconds; 

my $now = localtime(); 
my $yesterday = $now - ONE_HOUR*($now->hour + 12); 
say $yesterday->strftime('%b %d %Y'); 

Alternativement, vous pouvez utiliser le module DateTime comme décrit dans une réponse différente. Ce n'est pas un module de base, cependant.

Answer 4

use DateTime qw(); 
DateTime->now->subtract(days => 1); 

L'expression de la deuxième ligne renvoie un objet DateTime.

Answer 5

Aussi tentant que de soustraire une journée de secondes de l'heure actuelle, il y a des moments où cela donnera la mauvaise réponse (secondes intercalaires, DST, et éventuellement d'autres). Je trouve plus facile de laisser simplement strftime (disponible dans le module de base Perl 5 POSIX) prendre soin de tout cela pour moi.

#!/usr/bin/perl 

use strict; 
use warnings; 

use Time::Local; 
use POSIX qw/strftime/; 

#2010-03-15 02:00:00 
my ($s, $min, $h, $d, $m, $y) = (0, 0, 0, 15, 2, 110); 

my $time  = timelocal $s, $min, $h, $d, $m, $y;  
my $today  = strftime "%Y-%m-%d %T", localtime $time; 
my $yesterday = strftime "%Y-%m-%d %T", $s, $min, $h, $d - 1, $m, $y; 
my $oops  = strftime "%Y-%m-%d %T", localtime $time - 24*60*60; 
print "$today -> $yesterday -> $oops\n"; 

Answer 6

La solution proposée par la plupart des utilisateurs est incorrecte!

localtime(time() - 24*60*60) 

Le pire chose que vous pouvez faire est de supposer que 1 jour = 86400 secondes.

Exemple: fuseauHoraire Amérique/New_York, la date est Mon Apr 3 00:30:00 2006

timelocal nous donne

localtime (1144038600-86400) = Sat avril 1 23:30:00 EST 2006

oups!

Le droit et la seule solution est de laisser normaliser le fonctionnement du système des valeurs

$prev_day = timelocal(0, 0, 0, $mday-1, $mon, $year); 

Ou laisser les cadres datetime (DateTime, Class::Date, etc) font la même chose.

C'est tout.

Answer 7

This is how I do it. 

#!/usr/bin/perl 

use POSIX qw(strftime); 

$epoc = time(); 
$epoc = $epoc - 24 * 60 * 60; 

$datestring = strftime "%F", localtime($epoc); 

print "Yesterday's date is $datestring \n";