Modification des paramètres de l'imprimante dans les rapports au moment de l'exécution

Question

Peut-on modifier les paramètres de l'imprimante lors de l'exécution dans SSRS 2008?

Par exemple, si un rapport est sur le papier de format légal, mais je veux imprimer sur A4 paysage ou légal au moment de l'exécution, en fonction d'un paramètre qui est passé dans.

Answer 1

La réponse est que non, vous ne pouvez pas sauf si vous écrivez votre propre solution. Le contrôle du visualiseur de rapports ne prend pas cela en charge. Vos options sont soit de créer une solution d'impression personnalisée, soit de manipuler votre fichier RDLC pour modifier les paramètres manuellement. Si vous décidez de modifier le fichier RDLC à la volée, vous devez charger le fichier RDLC en mémoire, modifier le fichier XML pour spécifier les nouveaux paramètres de page, puis recharger le fichier RDLC dans le visualiseur de rapports.

Si vous décidez de faire l'impression manuelle, voici un code VB.NET pour vous aider à démarrer:

Dim m_pageSettings As PageSettings   'Stores page settings for printout 
    Dim m_currentPage As Integer    'Used for index of pages 
    Private m_pages As New List(Of Stream)() 'Stores a stream for each pages 

    'Event fires when printDocument starts printing - reset page index to zero 
    Private Sub PrintDocument1_BeginPrint(ByVal sender As System.Object, ByVal e As System.Drawing.Printing.PrintEventArgs) Handles PrintDocument1.BeginPrint 
    m_currentPage = 0 
    End Sub 

    'Function that prints all the pages included in the report 
    Private Sub PrintDocument1_PrintPage(ByVal sender As System.Object, ByVal e As System.Drawing.Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage 
    Dim pageToPrint As Stream = m_pages(m_currentPage) 
    pageToPrint.Position = 0 

    Dim pageMetaFile As Metafile = New Metafile(pageToPrint)  'create an image(metafile) of the report page 
    Using (pageMetaFile) 
     'Create a rectangle the size of our report - include margins 
     ' Dim adjustedRect As Rectangle = New Rectangle(_ 
     ' e.PageBounds.Left - CType(e.PageSettings.HardMarginX, Integer), _ 
     ' e.PageBounds.Top - CType(e.PageSettings.HardMarginY, Integer), _ 
     ' e.PageBounds.Width, _ 
     ' e.PageBounds.Height) 

     Dim adjustedRect As Rectangle = New Rectangle(_ 
    e.PageBounds.Left, _ 
    e.PageBounds.Top, _ 
    e.PageBounds.Width, _ 
    e.PageBounds.Height) 

     e.Graphics.FillRectangle(Brushes.White, adjustedRect) 'Fill rectangle with WHITE background 
     e.Graphics.DrawImage(pageMetaFile, adjustedRect)  'Draw report in rectangle - this will be printed 
     m_currentPage = m_currentPage + 1 
     e.HasMorePages = m_currentPage < m_pages.Count   'If more pages are left - keep processing 
    End Using 
    End Sub 

    'Event fires when PrintDocument queries for PageSettings. Return a copy of m_pagesettings. 
    Private Sub PrintDocument1_QueryPageSettings(ByVal sender As System.Object, ByVal e As System.Drawing.Printing.QueryPageSettingsEventArgs) Handles PrintDocument1.QueryPageSettings 
    e.PageSettings = CType(m_pageSettings.Clone, PageSettings) 
    End Sub 

    'Render the report in a EMF - This function creates metafiles(images) of each page in the report 
    Private Sub RenderAllLocalReportPages(ByVal localReport As LocalReport) 
    Dim deviceInfo As String = CreateEMFDeviceInfo() 'Enhanced MetaFile 
    Dim warnings As Warning() = Nothing 
    m_pages.Clear() 
    localReport.Render("IMAGE", deviceInfo, AddressOf LocalReportCreateStreamCallback, warnings) 
    End Sub 

    'Callback function used with RenderAllLocalReportPages 
    Private Function LocalReportCreateStreamCallback(ByVal name As String, ByVal extension As String, ByVal encoding As Encoding, ByVal mimeType As String, ByVal willSeek As Boolean) As Stream 
    Dim stream As New MemoryStream() 
    m_pages.Add(stream) 
    Return stream 
    End Function 

    Private Function CreateEMFDeviceInfo() As String 
    Dim paperSize As PaperSize = m_pageSettings.PaperSize 
    Dim margins As Margins = m_pageSettings.Margins 

    'The device info string defines the page range to print as well as the size of the page. 
    'A start and end page of 0 means generate all pages. 
    Return String.Format(CultureInfo.InvariantCulture, "<DeviceInfo><OutputFormat>emf</OutputFormat><StartPage>0</StartPage><EndPage>0</EndPage><MarginTop>{0}</MarginTop><MarginLeft>{1}</MarginLeft><MarginRight>{2}</MarginRight><MarginBottom>{3}</MarginBottom><PageHeight>{4}</PageHeight><PageWidth>{5}</PageWidth></DeviceInfo>", ToInches(margins.Top), ToInches(margins.Left), ToInches(margins.Right), ToInches(margins.Bottom), ToInches(paperSize.Height), ToInches(paperSize.Width)) 
    End Function 

    'Convert report printing size to inches 
    Private Shared Function ToInches(ByVal hundrethsOfInch As Integer) As String 
    Dim inches As Double = hundrethsOfInch/100.0R 
    Return inches.ToString(CultureInfo.InvariantCulture) & "in" 
    End Function 

Espérons que cela aide.