Dans un fichier batch, est-il possible de remplacer cette utilisation de SED et TR par une boucle for?

Question

le fichier de commandes:

@echo. 
@set curdrive=%~d0 
@path | %curdrive%\utils\sed -e "s/PATH=//" | %curdrive%\utils\tr ; \n 
@echo. 

sortie de l'échantillon (un élément de trajet pour chaque ligne):

C:\cheeso\bin 
C:\Perl\bin 
c:\utils 
C:\Windows\system32 
C:\Windows 
C:\Windows\System32\Wbem 
c:\Program Files\Microsoft SQL Server\90\Tools\binn\ 
c:\.net3.5 
c:\.net2.0 
c:\vs2008\common7\IDE 
c:\netsdk2.0\bin 

Ce fichier de commandes dépend de la sed.exe et la tr.exe de UnxUtils. Je voudrais faire la même chose en utilisant seulement les commandes intégrées et les programmes inclus avec Windows. Puis-je le faire? Astuces?

Answer 1

setlocal 
SET _Path="%Path:;=";"%" 
FOR %%a IN (%_Path%) DO ECHO  %%~a 
endlocal 

Answer 2

Attention, l'abus de récursion avant:

@echo off 

call :one "%PATH%" 
goto :eof 

:one 
for /f "tokens=1,* delims=;" %%i in (%1) do (
    echo %%i 
    if not "%%j"=="" call :one "%%j" 
) 

Answer 3

est ici une version non récurrente. Pas vraiment mieux, mais je me sentais comme à la recherche d'une autre solution:

SETLOCAL ENABLEDELAYEDEXPANSION ENABLEEXTENSIONS 
:again 
FOR /F "delims=;" %%I IN ("%PATH%") DO ECHO %%I & SET PATH=!PATH:%%I;=! 
IF DEFINED PATH GOTO :again 
ENDLOCAL 

Je crois que cela ne fonctionne que pour Windows XP, 2003 Server et plus récent.

Answer 4

j'ai commencé à utiliser:

@ECHO OFF 
SETLOCAL ENABLEDELAYEDEXPANSION ENABLEEXTENSIONS 
set tpath=%path%; 
echo. 
:again 
FOR /F "delims=;" %%I IN ("%TPATH%") DO (
    echo %%I 
    set TPATH=!TPATH:%%I;=! 
) 
IF DEFINED TPATH GOTO :again 

ENDLOCAL 

Mais alors décidé que c'était plus simple:

setlocal 
set _path="%PATH:;=" "%" 
for %%p in (%_path%) do if not "%%~p"=="" echo  %%~p 
endlocal 

Answer 5

J'ai essayé sur mon serveur Windows 2003 et cela a fonctionné. Voici le contenu de mon showpath.cmd:

@echo off 
for %%p in (%PATH%) do echo %%p