Perl 6 - Est-il possible de créer un trait d'attribut qui définit un méta-attribut?

Question

J'essaie de créer un trait d'attribut. Le cas d'utilisation consiste à marquer certains attributs d'une classe comme "crudable" dans le contexte d'un mappage objects-to-documents alors que d'autres ne le sont pas.

role crud { 
    has Bool $.crud is default(True); 
} 

multi trait_mod:<is>(Attribute $a, crud, $arg) { 
    $a.container.VAR does crud($arg); 
} 

class Foo { 
    has $.bar is rw; 

    # Provide an extra nested information 
    has $.baz is rw is crud(True); 
} 

En lisant et en adaptant some example code, je réussi à obtenir quelque chose qui semble faire ce que je veux. Voici a snippet with test case.

Quand j'instancier un nouveau Foo objet et définissez l'attribut $.bar (qui is pas crud), ça ressemble à ça:

.Foo @0 
├ $.bar is rw = 123456789 
└ $.baz is rw = .Scalar+{crud} @1 
    └ $.crud +{crud} = True 

Ce que je comprends est que l'attribut $.baz a ce que j'appelle meta-attribut qui est indépendant de sa valeur potentielle.

Cela me semble bon (si j'ai bien compris ce que j'ai fait ici et que mes traits ne sont pas un hack sale). Il est possible d'atteindre $foo.baz.crud, soit True. Cependant, je ne comprends pas très bien ce que veut dire , et si je peux y mettre quelque chose et comment.

Lorsque je tente de définir l'attribut $.baz instance, cette erreur est renvoyée:

Cannot modify an immutable Scalar+{crud} (Scalar+{crud}.new(crud => Bool::True)) 
    in block <unit> at t/08-attribute-trait.t line 30 

Note: Ceci est la chose la plus proche à une solution de travail que je réussi à obtenir. Je n'ai pas besoin de paramètres de crud différents pour différentes instances de classes Foo instanciées.

Je ne veux jamais changer la valeur du booléen, en fait, une fois l'objet instancié, juste fournissant aux attributs avec is crud. Je ne suis même pas intéressé de passer une valeur True ou False comme argument: s'il serait possible de simplement définir l'attribut de trait booléen à True par défaut, cela suffirait. Je ne l'ai pas réussi à le faire si, comme:

multi trait_mod:<is>(Attribute $a, :$crud!) { 
    # Something like this 
    $a.container.VAR does set-crud; 
} 

class Foo { 
    has $.bar is rw; 
    has $.baz is rw is crud; 
} 

Suis-je essayer de faire quelque chose d'impossible? Comment pourrais-je adapter ce code pour réaliser ce cas d'utilisation?

Answer 1

Il y a plusieurs choses qui se passent ici. Tout d'abord, la signature du trait_mod semble être fausse. Deuxièmement, il semble y avoir une mauvaise interaction lorsque le nom d'un trait est le même qu'un rôle existant. Je crois que cela devrait être une exception de la NYI, mais apparemment, ça ne va pas dans l'analyse, ou ça ne va pas dans le fait d'essayer de produire le message d'erreur.

Quoi qu'il en soit, je pense que c'est ce que vous voulez:

role CRUD {}; # since CRUD is used as an acronym, I chose to use uppercase here 

multi trait_mod:<is>(Attribute:D $a, :$crud!) { # note required named attribute! 
    $a.^mixin: CRUD if $crud; # mixin the CRUD role if a True value was given 
} 

class A { 
    has $.a is crud(False); # too bad "is !crud" is invalid syntax 
    has $.b is crud; 
} 

say "$_.name(): { $_ ~~ CRUD }" for A.^attributes; # $!a: False, $!b: True 

Hope this helps.