COUNTIF et imprimez la chaîne comptée

Question

Besoin de votre expertise VBA dans l'exécution de la tâche ci-dessous. J'ai besoin de faire un "MACORS" countif de villes sur une colonne et d'imprimer chaque ville à côté du numéro. J'ai ce code:

Public Sub CountLocation() 

Range("V2").Select 

Selection.End(xlDown).Select 
lastcell = ActiveCell.Address 

ActiveCell.Offset(2, 0).Value = "=countif(V2:" + lastcell + ", ""Zurich"")" 
ActiveCell.Offset(2, 1).Value = "Zurich" 
ActiveCell.Offset(3, 0).Value = "=countif(V2:" + lastcell + ", ""Armonk"")" 
ActiveCell.Offset(3, 1).Value = "Armonk" 
ActiveCell.Offset(4, 0).Value = "=countif(V2:" + lastcell + ", ""Hong Kong"")" 
ActiveCell.Offset(4, 1).Value = "Hong Kong" 
ActiveCell.Offset(5, 0).Value = "=countif(V2:" + lastcell + ", ""London"")" 
ActiveCell.Offset(5, 1).Value = "London" 
ActiveCell.Offset(6, 0).Value = "=countif(V2:" + lastcell + ", ""Madrid"")" 
ActiveCell.Offset(6, 1).Value = "Madrid" 

End Sub 

Mon problème est que j'ai environ 90 villes « possibles » dans une feuille et diffère des autres feuilles. Mon code ci-dessus imprime une ville qui ne figure pas dans une feuille spécifique.

Merci pour vous aider

Answer 1

Mettez les villes dans un tableau et une boucle ce tableau. Aussi, avoir la gamme de comptage comme une gamme. Il y a un test If pour plus de 0 donc n'écrira pas la ville si elle n'est pas présente.

Tous ensemble:

Option Explicit 

Public Sub CountLocation() 

    Dim wb As Workbook 
    Dim ws As Worksheet 
    Dim countRange As Range 

    Set wb = ThisWorkbook 
    Set ws = wb.ActiveSheet 'Change as appropriate 

    Dim lastRow As Long 
    lastRow = ws.Range("V2").End(xlDown).Row 'Update: Extracted this into a variable 

    Set countRange = ws.Range(ws.Cells(2, "V"), ws.Cells(lastRow, "V")) 

    Dim Cities() 
    Cities = Array("Zurich", "Armonk", "Hong Kong", "London", "Madrid") 

    Dim city As Long 
    Dim counter As Long 
    Dim startRange As Range 

    Set startRange = ws.Cells(lastRow, "V").Offset(2, 0) 

    counter = 2 

    For city = LBound(Cities) To UBound(Cities) 
     If Application.WorksheetFunction.CountIf(countRange, Cities(city)) > 0 Then 
     startRange.Offset(counter, 0) = Application.WorksheetFunction.CountIf(countRange, Cities(city)) 
     startRange.Offset(counter, 1) = Cities(city) 
     counter = counter + 1 
     End If 

    Next city 

End Sub 

Remarques sur les différentes parties:

Ce qui suit récupère la dernière ligne utilisée avant une cellule vide dans la colonne V à partir de V2. Si vous avez des cellules vides avant la dernière cellule utilisée, vous obtiendrez une dernière ligne incorrecte.

lastRow = ws.Range("V2").End(xlDown).Row, "V") 

régler la plage de compter sur de V2 à la dernière ligne utilisée en V avec:

Set countRange = ws.Range(ws.Cells(2, "V"),ws.Cells(lastRow, "V")) 

Définir où vous allez commencer à écrire les résultats avec:

Set startRange = ws.Cells(lastRow, "V").Offset(2, 0) 

Boucle le tableau des villes en comptant les occurrences d'une ville particulière dans la plage de comptage avec:

Application.WorksheetFunction.CountIf(countRange, Cities(city)) 

Retourne dans une instruction IF pour voir si count est> 0.

If Application.WorksheetFunction.CountIf(countRange, Cities(city)) > 0 

écrire à la feuille de compensation de la première position de la pâte par une ligne à chaque fois à l'aide d'une variable compteur:

startRange.Offset(counter, 0) = Application.WorksheetFunction.CountIf(countRange, Cities(city)) 
startRange.Offset(counter, 1) = Cities(city)