Convertisseur de bits VBA

Question

Je voudrais savoir comment utiliser la méthode bitconverter dans Excel VBA. Je voudrais convertir 4 octets chacun placé dans une cellule de différence dans un entier de 32 bits en utilisant BitConverter.ToInt32.

Quelqu'un peut-il m'aider avec un exemple à utiliser dans VBA? Je pense que je suis aux prises avec la syntaxe.

Merci

Answer 1

• Avec CopyMemory:

  Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (ByRef Destination As Any, ByRef Source As Any, ByVal Length As Long) 
  
  Public Function BytesToLong(b() As Byte) As Long 
      CopyMemory BytesToLong, b(LBound(b)), 4 
  End Function 
  

• Sans CopyMemory 1:

  Private Type thebytes 
      b(1 To 4) As Byte 
  End Type 
  
  Private Type thelong 
      l As Long 
  End Type 
  
  
  Public Function BytesToLong(b() As Byte) As Long 
      Dim tb As thebytes, tl As thelong 
      Dim lb As Long 
  
      lb = LBound(b) 
      tb.b(1) = b(lb) 
      tb.b(2) = b(lb + 1) 
      tb.b(3) = b(lb + 2) 
      tb.b(4) = b(lb + 3) 
  
      LSet tl = tb 
  
      BytesToLong = tl.l 
  End Function 
  

• Sans CopyMemory 2:

  Public Function BytesToLong(b() As Byte) As Long 
      Dim lb As Long 
      lb = LBound(b) 
  
      If (b(lb + 3) And &H80) = &H80 Then 
      BytesToLong = (b(lb) + b(lb + 1) * &H100& + b(lb + 2) * &H10000 + (b(lb + 3) And Not &H80) * &H1000000) Or &H80000000 
      Else 
      BytesToLong = b(lb) + b(lb + 1) * &H100& + b(lb + 2) * &H10000 + b(lb + 3) * &H1000000 
      End If 
  
  End Function