Comment puis-je faire la pagination dans mon script Perl CGI?

Question

J'ai une page CGI avec une table qui est peuplée en récupérant les données de la base de données, dans un mot c'est comme un DATAGRID.

Et juste à la fin en bas à droite de la grille tha je besoin d'un lien comme « First < < 1 2 >> Dernière » ou comme « | < <>> | » en cliquant que je peux naviguer çà et là la enregistrements. Et j'ai l'intention d'avoir "10" enregistrements par page.

En surfant j'ai eu un morceau de code que je vais coller dans le champ de code. Mais le problème est qu'il affiche le lien de pagination quelque chose comme ceci "1 2 3 4 5 ..et ainsi de suite". Mais je ne suis pas prêt à avoir ce format de pagination, car le nombre d'enregistrements augmente la longueur du lien continue également d'augmenter. Donc, ce code peut-il être modifié au format que j'ai l'intention d'avoir?

#!C:\perl\bin\perl.exe -wT 

use CGI; 
use CGI::Carp qw(warningsToBrowser fatalsToBrowser); 
use strict; 
use warnings; 
use DBI; 
my $query = new CGI; 
my $bornum; 
my $itemnum; 
my $i; 
my @overduedata; 
my $pageNum =$query->param('pageNum'); 
print "Content-Type: text/html\n\n"; 

unless($pageNum) { 
    $pageNum=0; 
} 
my $offset=$query->param('offset'); 
unless($offset) { 
    $offset=10; 
} 
$i=0; 
my $numOfRec = 100; 
while ($i < $numOfRec){ 
    $bornum = "bornum" . $i; 
    $itemnum = "itmnum" . $i; 
    push (@overduedata, { bornum => $bornum, itemnum => $itemnum }); 
    $i = $i + 1; 
} 

print "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=iso-8859-1\">"; 
print "\n<form>"; 
print "\nNo: of records per page : <input type=text name=offset>"; 
print "\n<input type=submit value=submit>"; 
print "\n</form>"; 
print "\n<br> No: of rec per page = " . $offset . " -- pageNum = " . $pageNum ; 
print "<table border=1>"; 

my $startDisplay = ($pageNum) * $offset; 
my $endDisplay = ($pageNum + 1) * $offset; 
$i = $startDisplay; 
while ($i < $endDisplay){ 
    print "<tr><td>" . $i . "</td><td>" . $overduedata[$i]->{'bornum'} . "</td><td>" . 
      $overduedata[$i]->{'itemnum'} . "</td></tr>"; 
    $i = $i + 1; 
} 
print "</table>"; 

my $numofPages = $numOfRec/$offset; 
$i = 0; 
print "<table border=1><tr>"; 
while ($i < $numofPages){ 
    print "<td> <a href = ?pageNum=" . $i . "&offset=" . $offset . ">" . 
      $i . "</a></td>"; 
    $i = $i + 1; 
} 
print "<tr></table>"; 


--------------------------------------------------------------------------------------- 

Answer 1

Si tout ce que vous n'aimez pas sont les liens, alors vous pouvez modifier la boucle à la fin pour imprimer les liens que vous voulez. C'est juste une question de manipulation des numéros de page.

(Je ne sais pas où vous avez obtenu ce code, mais "page 0" n'est pas facile à utiliser même pour les programmeurs qui travaillent avec 0 offset depuis des décennies! Et si vous connaissez la taille de votre page, le décalage est les données inutiles, et comme il indique plus la taille de la page, il est également mal)

Ainsi, le plus simple changement est la suivante:.

my $pageN; 
if ($pageNum > 0) { 
    print q[<td><a href="?pageNum=1">|&lt;</a></td>]; 
    $pageN = $pageNum - 1; 
    print qq[<td><a href="?pageNum=$pageN">&lt;</a></td>]; 
} 
else { # don't link to the current page 
    print q[<td><span class="currentpage">|&lt;</span></td>]; 
    print q[<td><span class="currentpage">&lt;</span></td>]; 

} 

if ($pageNum < ($numofPages - 1)) { 
    $pageN = $pageNum + 1; 
    print qq[<td><a href="?pageNum=$pageN">&gt;</a></td>]; 
    print qq[<td><a href="?pageNum=$numofPages">&gt;|</a></td>]; 
} 
else { # don't link to the current page 
    print q[<td><span class="currentpage">&gt;</span></td>]; 
    print q[<td><span class="currentpage">&gt;|</span></td>]; 
} 

Juste une remarque: pas un lien vers la page en cours permet une compréhension utilisateur plus rapide où ils sont dans la liste. Aussi, cela signifie qu'ils ne peuvent pas frapper le serveur juste pour recharger la page. Vous voulez être en mesure de communiquer clairement qu'ils sont déjà sur la première ou la dernière page.

Cependant, une partie de votre question est de savoir comment le faire en Perl CGI. À l'aide réelle CGI Perl, vous n'avez pas print '<td>'. Vous utilisez des méthodes pour créer des tags:

my @cells 
    = map { 
     my ($page, $text) = @$_; 
     ($query->td(
       $page > 0 and $page <= $numofPages and $pageNum != $page 
        ? $query->a({ href => "?pageNum=$page" }, $text) 
        : $query->span({ -class => 'currentpage' }, $text) 
     ), "\n" 
     ) 
    } ([ 1     => '|&lt;' ] 
     , [ ($pageNum - 1) => '&lt;' ] 
     , [ ($pageNum + 1) => '&gt;' ] 
     , [ $numofPages  => '&gt;|' ] 
    ) 
    ; 

print $query->table( 
     { -class => 'pagenav', -border => 1 } 
    , $query->Tr({ -class => 'pagenavrow' } @cells) 
    ); 

Vous devez noter que je aussi modifié pour que votre première page est # 1 ainsi.

Comme vous avez indiqué que vous voudrez peut-être quelques numéros de page, ainsi, le seul ajustement je devais faire était de calculer la plage min-max, comme ceci:

use List::Util qw<max min>; 
my $min_page = max(1, $pageNum - 5); 
my $max_page = min($numofPages, $min_page + 10); 
$min_page = max(1, min($min_page, $max_page - 10)); 

Et utiliser ces valeurs pour ajouter liens page numérotée à la liste transmise à la création map@cells:

([ 1     => '|<' ] 
    , [ ($pageNum - 1) => '<' ] 
    , (map { [ $_ => $_ ] } $min_page..$max_page) 
    , [ ($pageNum + 1) => '>' ] 
    , [ $numofPages  => '>|' ] 
) 

Answer 2

Je pense que vous voulez probablement Data::Pageset.