Comment copier des URL d'un document Word à un autre document?

Question

J'ai un document Word bourré de codes et d'URL qui se trouvent partout dans le document.

J'ai essayé de trouver comment je peux extraire toutes les URL dans ce document Word et les faire coller sur un autre document?

les URL ont tous le même site qui commence par https://subdomain.domain.com ..

le problème est .. je aurai besoin le lien URL complète qui se termine généralement par un .jpg

j'ai essayé googler mais tous Je trouve des solutions sur la façon dont les URL des liens hypertexte peuvent être extraites. Je n'ai pas trouvé de solution à ma situation et j'espère que vous pourrez aider!

Answer 1

Cela analyser le document et trouver toutes les URL pour vous et la sortie du tableau à une nouvelle Document:

Option Explicit 

Sub FindLinks() 
    Dim p As Paragraph 
    Dim vSplit As Variant 
    Dim nIndex As Integer 
    Dim sURLs() As String 
    ReDim sURLs(0) 

    ' find each URL and add it to an array 
    For Each p In ActiveDocument.Paragraphs 
    vSplit = Split(p.Range, " ") 
    For nIndex = 0 To UBound(vSplit) 
     If InStr(vSplit(nIndex), "https://stackoverflow.com") > 0 Then 
     ReDim Preserve sURLs(UBound(sURLs) + 1) 
     sURLs(UBound(sURLs)) = Replace(vSplit(nIndex), "src=", "") 
     End If 
    Next 
    Next 

    ' create a new document and output the array 
    Dim sURL As Variant 
    Documents.Add 
    For Each sURL In sURLs 
    Selection.TypeText sURL 
    Selection.TypeParagraph 
    Next 

End Sub 

Answer 2

Je modifié le code pour envoyer les résultats à C: \ temp \ my_links.txt. Vous pouvez modifier le code pour changer la destination.

Public Sub GetUrls() 
    Dim r As Range 
    Dim outfile As String 

    outfile = "C:\temp\my_links.txt" 
    Open outfile For Output As #1 
    Set r = ActiveDocument.Range 
    r.Select 

    With Selection.Find 
     .ClearFormatting 
     .Text = "https://subdomain.domain.com/*.jpg" 
     .Forward = True 
     .Wrap = wdFindStop 
     .MatchWildcards = True 
     .MatchCase = False 
     .MatchWholeWord = False 
     .MatchAllWordForms = False 
     .MatchSoundsLike = False 
    End With 

    Do While Selection.Find.Execute 
     Write #1, Selection.Text 
    Loop 

    Close #1 
End Sub 

Quand j'exécuter sur un fichier de test, je reçois ceci dans le fichier de sortie:

"https://subdomain.domain.com/res1/joe.jpg" 
"https://subdomain.domain.com/res2/cat.jpg" 

espoir qui aide.