Exécuter une procédure stockée dans SQL Developer?

Question

J'essaie d'exécuter une procédure stockée avec plusieurs paramètres d'entrée et de sortie. La procédure peut uniquement être affichée dans le panneau Connexions en naviguant sur Autres utilisateurs | | Forfaits | | Si je clique avec le bouton droit de la souris, les éléments de menu sont "Ordre des membres par ..." et "Créer un test unitaire" (grisé). La possibilité de "lancer" la procédure ne semble pas possible lorsque l'utilisateur y accède.

J'ai essayé de trouver un exemple de la façon de créer un bloc anonyme afin que je puisse exécuter la procédure en tant que fichier SQL, mais je n'ai rien trouvé qui fonctionne.

Est-ce que quelqu'un sait comment je peux exécuter cette procédure à partir de SQL Developer? J'utilise la version 2.1.1.64.

Merci d'avance!

EDIT 1:

La procédure que je veux appeler a cette signature:

user.package.procedure(
    p_1 IN NUMBER, 
    p_2 IN NUMBER, 
    p_3 OUT VARCHAR2, 
    p_4 OUT VARCHAR2, 
    p_5 OUT VARCHAR2, 
    p_6 OUT NUMBER) 

Si j'écris mon bloc anonyme comme ceci:

DECLARE 
    out1 VARCHAR2(100); 
    out2 VARCHAR2(100); 
    out3 VARCHAR2(100); 
    out4 NUMBER(100); 
BEGIN 
    EXECUTE user.package.procedure (33,89, :out1, :out2, :out3, :out4); 
END; 

Je reçois l'erreur :

Bind Varialbe "out1" is NOT DECLCARED 
anonymous block completed 

J'ai essayé d'initialiser la série * variables:

out1 VARCHAR2(100) := ''; 

mais obtenir la même erreur:

EDIT 2:

Sur la base de la réponse d'Alex, j'ai essayé de retirer les colons de en face des paramètres et obtenir ceci:

Error starting at line 1 in command: 
DECLARE 
    out1 VARCHAR2(100); 
    out2 VARCHAR2(100); 
    out3 VARCHAR2(100); 
    out4 NUMBER(100); 
BEGIN 
    EXECUTE user.package.procedure (33,89, out1, out2, out3, out4); 
END; 
Error report: 
ORA-06550: line 13, column 17: 
PLS-00103: Encountered the symbol "USER" when expecting one of the following: 

    := . (@ % ; immediate 
The symbol ":=" was substituted for "USER" to continue. 
06550. 00000 - "line %s, column %s:\n%s" 
*Cause: Usually a PL/SQL compilation error. 
*Action: 

Answer 1

Avec des types de paramètres simples (c'est-à-dire pas de refcurseurs, etc.) Vous pouvez faire quelque chose comme ceci:

SET serveroutput on; 
DECLARE 
    InParam1 number; 
    InParam2 number; 
    OutParam1 varchar2(100); 
    OutParam2 varchar2(100); 
    OutParam3 varchar2(100); 
    OutParam4 number; 
BEGIN 
    /* Assign values to IN parameters */ 
    InParam1 := 33; 
    InParam2 := 89; 

    /* Call procedure within package, identifying schema if necessary */ 
    schema.package.procedure(InParam1, InParam2, 
     OutParam1, OutParam2, OutParam3, OutParam4); 

    /* Display OUT parameters */ 
    dbms_output.put_line('OutParam1: ' || OutParam1); 
    dbms_output.put_line('OutParam2: ' || OutParam2); 
    dbms_output.put_line('OutParam3: ' || OutParam3); 
    dbms_output.put_line('OutParam4: ' || OutParam4); 
END; 
/

---

Edité utiliser la spécification de l'OP, et une autre approche d'utiliser :var variables de liaison:

var InParam1 number; 
var InParam2 number; 
var OutParam1 varchar2(100); 
var OutParam2 varchar2(100); 
var OutParam3 varchar2(100); 
var OutParam4 number; 

BEGIN 
    /* Assign values to IN parameters */ 
    :InParam1 := 33; 
    :InParam2 := 89; 

    /* Call procedure within package, identifying schema if necessary */ 
    schema.package.procedure(:InParam1, :InParam2, 
     :OutParam1, :OutParam2, :OutParam3, :OutParam4); 
END; 
/

-- Display OUT parameters 
print :OutParam1; 
print :OutParam2; 
print :OutParam3; 
print :OutParam4; 

Answer 2

Exécution facile. Obtenir les résultats peut être difficile.

Jetez un oeil à cette question que je posais Best way/tool to get the results from an oracle package procedure

Le résumé de celui-ci va comme ceci.

En supposant que vous ayez un package nommé mypackage et une procédure appelée getQuestions. Il renvoie un refcursor et prend le nom d'utilisateur de la chaîne.

Tout ce que vous avez à faire est de créer un nouveau fichier SQL (nouveau fichier). Définissez la connexion et collez ce qui suit et exécutez.

var r refcursor; 
exec mypackage.getquestions(:r, 'OMG Ponies'); 
print r; 

Answer 3

Utilisation:

BEGIN 

    PACKAGE_NAME.PROCEDURE_NAME(parameter_value, ...); 

END; 

Remplacer "PACKAGE_NAME", "PROCEDURE_NAME" et "parameter_value" avec ce que vous avez besoin. Les paramètres OUT devront être déclarés avant.

Answer 4

ouvrir la procédure dans SQL Developer et lancez-le à partir de là. SQL Developer affiche le SQL qu'il exécute.

BEGIN 
    PROCEEDURE_NAME_HERE(); 
END; 

Answer 5

var out_para_name refcursor; 
execute package_name.procedure_name(inpu_para_val1,input_para_val2,... ,:out_para_name); 
print :out_para_name; 

Answer 6

ne peux pas croire, ce ne sera pas exécuter dans SQL Developer:

var r refcursor; 
exec PCK.SOME_SP(:r, 
'02619857'); 

print r; 

MAIS cela:

var r refcursor; 
exec TAPI_OVLASCENJA.ARH_SELECT_NAKON_PRESTANKA_REG(:r, '02619857'); 

print r; 

tout a évidemment être dans une ligne ..

Answer 7

Je n'ai pas réussi à obtenir @Alex Poole nswers travail. Cependant, par essais et erreurs, j'ai trouvé les travaux suivants (en utilisant SQL Developer version 3.0.04). Affichage ici au cas où il aide les autres:

SET serveroutput on; 

DECLARE 
    var InParam1 number; 
    var InParam2 number; 
    var OutParam1 varchar2(100); 
    var OutParam2 varchar2(100); 
    var OutParam3 varchar2(100); 
    var OutParam4 number; 

BEGIN 
    /* Assign values to IN parameters */ 
    InParam1 := 33; 
    InParam2 := 89; 

    /* Call procedure within package, identifying schema if necessary */ 
    schema.package.procedure(InParam1, InParam2, 
     OutParam1, OutParam2, OutParam3, OutParam4); 

    /* Display OUT parameters */ 
    dbms_output.put_line('OutParam1: ' || OutParam1); 
    dbms_output.put_line('OutParam2: ' || OutParam2); 
    dbms_output.put_line('OutParam3: ' || OutParam3); 
    dbms_output.put_line('OutParam4: ' || OutParam4); 
END; 

Answer 8

Utilisation de la version SQL Developer 4.0.2.15 Construire 15.21 les travaux suivants:

SET SERVEROUTPUT ON 
var InParam1 varchar2(100) 
var InParam2 varchar2(100) 
var InParam3 varchar2(100) 
var OutParam1 varchar2(100) 

BEGIN 
    /* Assign values to IN parameters */ 
    :InParam1 := 'one'; 
    :InParam2 := 'two'; 
    :InParam3 := 'three'; 

    /* Call procedure within package, identifying schema if necessary */ 
    schema.package.procedure(:InParam1, :InParam2, :InParam3, :OutParam1); 
    dbms_output.enable; 
    dbms_output.put_line('OutParam1: ' || :OutParam1); 
END; 
/

Answer 9

Pour ceux qui utilisent sqldeveloper 3+, dans le cas où vous avez manqué que:

SqlDeveloper dispose d'une fonction permettant d'exécuter directement la proc/fonction stockée, et les résultats affichés sont faciles à lire.

suffit de cliquer à droite sur le paquet/proc stocké/fonction stockée, cliquez sur Run et choisissez target être le proc/func que vous voulez exécuter, sqldeveloper va générer l'extrait de code à exécuter (de sorte que vous pouvez mettre votre entrée paramètres). Une fois exécuté, les paramètres de sortie sont affichés dans la moitié inférieure de la boîte de dialogue, et il a même un support intégré pour le curseur ref: le résultat du curseur sera affiché comme un onglet de sortie séparé.

Answer 10

Créer un bloc Pl/SQL peut être douloureux si vous avez beaucoup de procédures qui ont beaucoup de paramètres. Il y a un application écrit sur python qui le fait pour vous. Il analyse le fichier avec les déclarations de procédure et crée l'application Web pour des appels de procédure pratiques.

Answer 11

Aucune de ces autres réponses n'a fonctionné pour moi. Voici ce que je devais faire pour exécuter une procédure dans SQL Developer 3.2.20.10:

SET serveroutput on; 
DECLARE 
    testvar varchar(100); 
BEGIN 
    testvar := 'dude'; 
    schema.MY_PROC(testvar); 
    dbms_output.enable; 
    dbms_output.put_line(testvar); 
END; 

Et vous avez alors d'aller vérifier la table pour quel que soit votre proc était censé faire avec ce passé-dans la variable - - La sortie confirmera simplement que la variable a reçu la valeur (et théoriquement, l'a transmise au proc).

NOTE (différences avec le mien vs.autres):

• Pas : avant le nom de la variable
• Aucune mise .package. ou .packages. entre le nom de schéma et le nom de la procédure
• Non avoir à mettre un & dans la valeur de la variable.
• Pas en utilisant print partout
• Non Usure var pour déclarer la variable

Tous ces problèmes me laissait me gratter la tête pour la plus longue et ces réponses qui ont ces erreurs flagrantes sur être retirées et goudronné et à plumes.