Html.DropDownListPour ne pas se comporter comme prévu ASP.net MVC

Question

Je suis nouveau sur ASP.net MVC et j'ai du mal à faire fonctionner correctement les listes déroulantes.

j'avoir une vue fortement typé qui tente d'utiliser un Html.DropDownListFor comme suit:

<%=Html.DropDownListFor(Function(model) model.Arrdep, Model.ArrdepOptions)%> 

Je peuplant la liste avec une propriété dans mon modèle comme suit:

Public ReadOnly Property ArrdepOptions() As List(Of SelectListItem) 
    Get 
     Dim list As New List(Of SelectListItem) 
     Dim arriveListItem As New SelectListItem() 
     Dim departListItem As New SelectListItem() 
     arriveListItem.Text = "Arrive At" 
     arriveListItem.Value = ArriveDepart.Arrive 
     departListItem.Text = "Depart At" 
     departListItem.Value = ArriveDepart.Depart 
     Select Case Me.Arrdep 
      Case ArriveDepart.Arrive : arriveListItem.Selected = True 
      Case Else : departListItem.Selected = True 
     End Select 
     list.Add(departListItem) 
     list.Add(arriveListItem) 
     Return list 
    End Get 
End Property 

Le Select Case fonctionne find et il définit le SelectListItem comme sélectionné, mais lorsque ma vue affiche la liste déroulante, peu importe ce qui est marqué comme sélectionné, le HTML généré n'a rien sélectionné. Je suis évidemment en train de faire quelque chose de mal ou de manquer quelque chose, mais je ne peux pas pour la vie de comprendre ce que je veux dire.

Answer 1

Il s'avère que j'ai dû écrire un helper de liste déroulante. J'ai trouvé l'article here. Voici mon code au cas où quelqu'un d'autre en aurait besoin. Il est grossièrement traduit en VB à partir de l'exemple C# de l'article.

Imports System.Linq.Expressions 
Imports System.Runtime.CompilerServices 

Namespace Helpers 

    Public Module HtmlDropDownExtensions 

     <Extension()> _ 
     Public Function EnumDropDownList(Of TEnum)(ByVal htmlHelper As HtmlHelper, ByVal name As String, ByVal selectedValue As TEnum) As MvcHtmlString 

      Dim values As IEnumerable(Of TEnum) = [Enum].GetValues(GetType(TEnum)) 

      Dim list As New List(Of SelectListItem) 
      For Each value As TEnum In values 
       Dim selectListItem As New SelectListItem() 
       selectListItem.Text = value.ToString() 
       selectListItem.Value = value.ToString() 
       selectListItem.Selected = (value.Equals(selectedValue)) 
       list.Add(selectListItem) 
      Next 
      Dim items As IEnumerable(Of SelectListItem) = list 

      Return htmlHelper.DropDownList(name, items) 

     End Function 

     <Extension()> _ 
     Public Function EnumDropDownListFor(Of TModel, TEnum)(ByVal htmlHelper As HtmlHelper(Of TModel), ByVal expression As Expression(Of Func(Of TModel, TEnum))) As MvcHtmlString 

      Dim metadata As ModelMetadata = ModelMetadata.FromLambdaExpression(expression, htmlHelper.ViewData) 

      Dim values As IEnumerable(Of TEnum) = [Enum].GetValues(GetType(TEnum)) 

      Dim list As New List(Of SelectListItem) 
      For Each value As TEnum In values 
       Dim selectListItem As New SelectListItem() 
       selectListItem.Text = value.ToString() 
       selectListItem.Value = value.ToString() 
       selectListItem.Selected = (value.Equals(metadata.Model)) 
       list.Add(selectListItem) 
      Next 
      Dim items As IEnumerable(Of SelectListItem) = list 

      Return htmlHelper.DropDownListFor(expression, items) 

     End Function 

    End Module 

End Namespace 

Answer 2

Essayez ceci:

Public ReadOnly Property ArrdepOptions() As SelectList 
    Get 
     Dim list As New List(Of SelectListItem)() 
     Dim arriveListItem As New SelectListItem() 
     Dim departListItem As New SelectListItem() 
     arriveListItem.Text = "Arrive At" 
     arriveListItem.Value = ArriveDepart.Arrive 
     departListItem.Text = "Depart At" 
     departListItem.Value = ArriveDepart.Depart 
     list.Add(departListItem) 
     list.Add(arriveListItem) 
     Return New SelectList(list, Me.Arrdep) 
    End Get 
End Property 

Answer 3

Le type de paramètre du constructeur SelectList 4-ème est l'objet, mais il veut sans doute un objet du même type que les objets de la liste (param 1 er). Par conséquent, la syntaxe correcte doit être la suivante:

Public ReadOnly Property ArrdepOptions() As SelectList 
    Get 
    Dim list As New List(Of SelectListItem) 
    Dim arriveListItem As New SelectListItem() 
    Dim departListItem As New SelectListItem() 
    arriveListItem.Text = "Arrive At" 
    arriveListItem.Value = ArriveDepart.Arrive 
    departListItem.Text = "Depart At" 
    departListItem.Value = ArriveDepart.Depart 
    list.Add(departListItem) 
    list.Add(arriveListItem) 

    Select Case Me.Arrdep 
     Case ArriveDepart.Arrive : Return New SelectList(list, "Text", "Value", arriveListItem) 
     Case Else : Return New SelectList(list, "Text", "Value", departListItem) 
    End Select 

    End Get 
End Property