Clojure: Comment se reproduire lors d'une exception?

Question

J'essaye d'exécuter une fonction plusieurs fois avant d'abandonner les exceptions. Mais il n'est pas valide à Clojure de se reproduire à partir du bloc catch. Comment cela peut-il être réalisé?

(loop [tries 10] 
    (try 
    (might-throw-exception) 
    (catch Exception e 
     (when (pos? tries) (recur (dec tries)))))) 

java.lang.UnsupportedOperationException: Cannot recur from catch/finally 

Le mieux que je pouvais trouver est la solution maladroite suivante (emballage Func et de l'appeler)

(defn do-it [] 
    (try 
    (might-throw-exception) 
    (catch Exception e nil))) 

(loop [times 10] 
    (when (and (nil? (do-it)) (pos? times)) 
    (recur (dec times)))) 

Answer 1

macros appellent ...

Que diriez-vous ceci:

(defn try-times* 
    "Executes thunk. If an exception is thrown, will retry. At most n retries 
    are done. If still some exception is thrown it is bubbled upwards in 
    the call chain." 
    [n thunk] 
    (loop [n n] 
    (if-let [result (try 
         [(thunk)] 
         (catch Exception e 
         (when (zero? n) 
          (throw e))))] 
     (result 0) 
     (recur (dec n))))) 

(defmacro try-times 
    "Executes body. If an exception is thrown, will retry. At most n retries 
    are done. If still some exception is thrown it is bubbled upwards in 
    the call chain." 
    [n & body] 
    `(try-times* ~n (fn [] ~@body)))

Answer 2

L'idée de kotarak est la voie à suivre, mais cette question a chatouillé mon envie alors je voudrais fournir un riff sur le même thème que je préfère parce qu'elle ne pas utiliser la boucle/RECUR:

(defn try-times* [thunk times] 
    (let [res (first (drop-while #{::fail} 
           (repeatedly times 
              #(try (thunk) 
               (catch Throwable _ ::fail)))))] 
    (when-not (= ::fail res) 
     res))) 

et laisser les essayages fois macro comme il est. Si vous voulez permettre au thunk de renvoyer zéro, vous pouvez supprimer la paire let/when, et laisser :: fail représenter "la fonction failed n fois", tandis que nil signifie "la fonction retournée nil". Ce comportement serait plus souple mais moins pratique (l'appelant doit vérifier :: ne vois pas si cela a fonctionné plutôt que nulle), il serait peut-être mieux mis en œuvre comme second paramètre:

(defn try-times* [thunk n & fail-value] 
    (first (drop-while #{fail-value} ...))) 

Answer 3

ma proposition:

(defmacro try-times 
    "Retries expr for times times, 
    then throws exception or returns evaluated value of expr" 
    [times & expr] 
    `(loop [err# (dec ~times)] 
    (let [[result# no-retry#] (try [(do ~@expr) true] 
        (catch Exception e# 
        (when (zero? err#) 
         (throw e#)) 
        [nil false]))] 
     (if no-retry# 
     result# 
     (recur (dec err#)))))) 

imprimera "aucune erreur ici" une fois:

(try-times 3 (println "no errors here") 42) 

imprimera "essayer" 3 fois, puis jeter par zéro Divide:

(try-times 3 (println "trying") (/ 1 0)) 

Answer 4

Une autre solution, sans macro

(defn retry [& {:keys [fun waits ex-handler] 
       :or {ex-handler #(log/error (.getMessage %))}}] 
    (fn [ctx] 
    (loop [[time & rem] waits] 
     (let [{:keys [res ex]} (try 
           {:res (fun ctx)} 
           (catch Exception e 
           (when ex-handler 
            (ex-handler e)) 
           {:ex e}))] 
     (if-not ex 
      res 
      (do 
      (Thread/sleep time) 
      (if (seq rem) 
       (recur rem) 
       (throw ex)))))))) 

Answer 5

Une macro try-times est élégant, mais pour une seule fois, il suffit de tirer votre when hors du bloc try:

(loop [tries 10] 
    (when (try 
      (might-throw-exception) 
      false ; so 'when' is false, whatever 'might-throw-exception' returned 
      (catch Exception e 
      (pos? tries))) 
    (recur (dec tries))))