techniques dans git grep et vim

Question

Remarque: marqué comme wiki de communauté

Code I dans vim.

J'utilise git; et j'adore git grep.

Quelqu'un at-il un ensemble de techniques/scripts particulièrement intéressants pour utiliser git grep à l'intérieur de vim?

Lecteurs: veuillez augmenter les réponses impliquant vim + git grep; Veuillez répondre par des réponses downvote impliquant des éditeurs non-vim, et des éditeurs faisant référence à des outils externes autres que git grep.

Answer 1

vous avez cette VIM extension (créé par Timo Hirvonen en 2006!)

git grep <pattern> recherche un motif dans une branche git actuellement sélectionnée.
Ceci ajoute la commande :G <pattern> pour exécuter la commande depuis Vim.

func GitGrep(...) 
    let save = &grepprg 
    set grepprg=git\ grep\ -n\ $* 
    let s = 'grep' 
    for i in a:000 
    let s = s . ' ' . i 
    endfor 
    exe s 
    let &grepprg = save 
endfun 
command -nargs=? G call GitGrep(<f-args>) 

Vous pouvez également limiter la recherche aux fichiers correspondant à un motif (git fera la mise en correspondance de motif):

:G <pattern> -- '*.c' 

ajouts:

L'ajout suivant exécutera git grep sur le mot sous le curseur lorsque Ctrl + XG est enfoncé.

func GitGrepWord() 
    normal! "zyiw 
    call GitGrep('-w -e ', getreg('z')) 
endf 
nmap <C-x>G :call GitGrepWord()<CR> 

Answer 2

Vous avez également cet ensemble de commandes de vim, du projet Git git grep vim, de tjennings.
(inspiré du ack.vim : Plugin for the Perl module/CLI script 'ack' de Miles Sterrett)

let g:gitgrepprg="git\\ grep\\ -n" 

function! GitGrep(args) 
    let grepprg_bak=&grepprg 
    exec "set grepprg=" . g:gitgrepprg 
    execute "silent! grep " . a:args 
    botright copen 
    let &grepprg=grepprg_bak 
    exec "redraw!" 
endfunction 

function! GitGrepAdd(args) 
    let grepprg_bak=&grepprg 
    exec "set grepprg=" . g:gitgrepprg 
    execute "silent! grepadd " . a:args 
    botright copen 
    let &grepprg=grepprg_bak 
    exec "redraw!" 
endfunction 

function! LGitGrep(args) 
    let grepprg_bak=&grepprg 
    exec "set grepprg=" . g:gitgrepprg 
    execute "silent! lgrep " . a:args 
    botright lopen 
    let &grepprg=grepprg_bak 
    exec "redraw!" 
endfunction 

function! LGitGrepAdd(args) 
    let grepprg_bak=&grepprg 
    exec "set grepprg=" . g:gitgrepprg 
    execute "silent! lgrepadd " . a:args 
    botright lopen 
    let &grepprg=grepprg_bak 
    exec "redraw!" 
endfunction 

command! -nargs=* -complete=file GitGrep call GitGrep(<q-args>) 
command! -nargs=* -complete=file GitGrepAdd call GitGrepAdd(<q-args>) 
command! -nargs=* -complete=file LGitGrep call LGitGrep(<q-args>) 
command! -nargs=* -complete=file LGitGrepAdd call LGitGrepAdd(<q-args>) 

Answer 3

Vérifiez aussi fugitive.vim - A Git wrapper so awesome, it should be illegal
(qui est son étiquette en ligne officielle;)), de Tim Pope (voir le Git repo project):

Il comprend , parmi beaucoup d'autres commandes, une pour un git grep:

call s:command("-bar -bang -nargs=? -complete=customlist,s:EditComplete Ggrep :execute s:Grep(<bang>0,<q-args>)") 
call s:command("-bar -bang -nargs=* -complete=customlist,s:EditComplete Glog :execute s:Log('grep<bang>',<f-args>)") 

function! s:Grep(bang,arg) abort 
    let grepprg = &grepprg 
    let grepformat = &grepformat 
    let cd = exists('*haslocaldir') && haslocaldir() ? 'lcd ' : 'cd ' 
    let dir = getcwd() 
    try 
    execute cd.'`=s:repo().tree()`' 
    let &grepprg = s:repo().git_command('--no-pager', 'grep', '-n') 
    let &grepformat = '%f:%l:%m' 
    exe 'grep! '.a:arg 
    let list = getqflist() 
    for entry in list 
     if bufname(entry.bufnr) =~ ':' 
     let entry.filename = s:repo().translate(bufname(entry.bufnr)) 
     unlet! entry.bufnr 
     elseif a:arg =~# '\%(^\| \)--cached\>' 
     let entry.filename = s:repo().translate(':0:'.bufname(entry.bufnr)) 
     unlet! entry.bufnr 
     endif 
    endfor 
    call setqflist(list,'r') 
    if !a:bang && !empty(list) 
     return 'cfirst' 
    else 
     return '' 
    endif 
    finally 
    let &grepprg = grepprg 
    let &grepformat = grepformat 
    execute cd.'`=dir`' 
    endtry 
endfunction 

Answer 4

Toujours dans le même ensemble d'encapsulation Git (y compris git grep), vous avez:

MinSCM : An abstract front-end for Mercurial/Git/Bazaar, de Takeshi NISHIDA:
Voir ses Git repo

alt text http://bitbucket.org/ns9tks/vim-minscm/wiki/log.png

:MinSCMGrep[!]     (Default mapping: \sg) 

recherches pour motif spécifié et crée un | quickfix | liste.

occasion SCM commandes ~

• hg: grep -n
• git: grep -n -e
• bzr: (non disponible)

Answer 5

J'ai trouvé un gist que les résultats ouverts de git grep dans un quickfix fenêtre pour sauter autour:

<C-x><C-x> runs grep for the word under the cursor 
:G <word> runs grep 
:Gi <word> runs grep as case-insensitive 

il suffit d'ajouter le contenu de l'essentiel à votre fichier ~/.vimrc