CreateDir génère une exception dans QB64

Question

J'ai le code suivant qui renvoie parfois une erreur lors de la tentative de création d'un nouveau répertoire. Parfois, lorsque ce répertoire n'existe pas, il génère une erreur et ne crée pas le répertoire. J'aimerais savoir pourquoi?

DECLARE DYNAMIC LIBRARY "kernel32" 
    FUNCTION CreateDirectoryA% (F$, X$) 
    FUNCTION GetLastError&() 
END DECLARE 
F$ = "TEMPX" + CHR$(0) ' new directory to create 
x = CreateDirectoryA(F$, CHR$(0)) 
IF x = 0 THEN 
    IF GetLastError = &H3E6 THEN 
     PRINT "Invalid access to memory location." 
    END IF 
END IF 

Ce code a été écrit en QB64.

Answer 1

Puis je suis tombé sur un problème créant des sous-répertoires dans un chemin, donc j'écrit ceci:

DECLARE DYNAMIC LIBRARY "kernel32" 
    FUNCTION CreateDirectoryA% (F$, BYVAL X&&) 
    FUNCTION GetLastError&() 
END DECLARE 
DO ' get directory 
    PRINT "Dir";: INPUT Directory$ 
    IF Directory$ = "" THEN END 
    GOSUB CreateDir 
LOOP 
END 
CreateDir: 
' construct path 
Directory$ = RTRIM$(Directory$) 
IF RIGHT$(Directory$, 1) <> "\" THEN 
    Directory$ = Directory$ + "\" 
END IF 
' create path 
x = 0 
Next.Dir = INSTR(Directory$, "\") 
DO 
    IF Next.Dir = False THEN 
     EXIT DO 
    END IF 
    SubDir$ = LEFT$(Directory$, Next.Dir - 1) ' \tempx\t1\t2\t3\ 
    Next.Dir = INSTR(Next.Dir + 1, Directory$, "\") 
    ' make directory name 
    IF LEN(SubDir$) THEN 
     ' create directory 
     f$ = SubDir$ + CHR$(0) 
     x = CreateDirectoryA(f$, 0) 
     ' check error 
     IF x = 0 THEN 
      IF GetLastError& = &HB7 THEN ' ignore already exists 
       ' nul 
      ELSE 
       EXIT DO 
      END IF 
     END IF 
    END IF 
LOOP 
IF x = 0 THEN 
    PRINT "Error x"; HEX$(GetLastError&) 
ELSE 
    PRINT "Directory created." 
END IF 
RETURN 

De cette façon, si vous spécifiez un chemin qui n'existe pas, il va créer l'ensemble de chemin. Par exemple, \ Temp \ t1 \ t2 \ t3 si \ Temp n'existe pas.

Answer 2

Ce code Impose la création d'un répertoire lorsque l'exception x3E6 arrive mais n'explique pourquoi l'erreur se produit en premier lieu:

DECLARE DYNAMIC LIBRARY "kernel32" 
    FUNCTION CreateDirectoryA% (F$, X$) 
    FUNCTION GetLastError&() 
END DECLARE 
DO 
    F$ = "TEMPX" + CHR$(0) ' new directory to create 
    x = CreateDirectoryA(F$, CHR$(0)) 
    IF x THEN ' successful create 
     EXIT DO 
    END IF 
    IF x = 0 THEN 
     REM Test for Invalid access to memory location. 
     IF GetLastError = &H3E6 THEN 
      _DELAY .2 
     ELSE 
      EXIT DO 
     END IF 
    END IF 
LOOP 

Answer 3

Qu'est-ce que vous passez comme paramètre lpSecurityAttributes de CreateDirectoryA est une chaîne de longueur 0; les chaînes ont toujours des adresses mémoire, ce qui signifie que vous passez un pointeur non nul. Cela est interprété par CreateDirectoryA comme un pointeur vers un SECURITY_ATTRIBUTES structure avec son premier octet défini sur 0. Les autres octets de la structure sont de la mémoire que vous n'avez pas initialisée, ce qui signifie que le premier champ nLength de la structure peut être quelque chose comme 0xFFFFFF00, qui est 4294967040 — une taille invalide. Le champ lpSecurityDescriptor de cette structure est vraisemblablement rempli d'octets (éventuellement accessibles par votre programme, mais peut-être pas), ce qui peut être à l'origine du problème.

Vous pouvez facilement y remédier:

' X%& may also be written X AS _OFFSET. 
FUNCTION CreateDirectoryA% (F$, BYVAL X%&) 

... 

x = CreateDirectoryA(F$, 0) 

Il en résulte le passage d'un pointeur NULL correctement. Le mot-clé BYVAL est nécessaire, sinon vous passez un pointeur à la valeur _OFFSET (parce que tout dans QB64 est passé par pointeur sauf si vous utilisez le mot-clé BYVAL, les chaînes et les types définis par l'utilisateur ne peuvent pas être passés BYVAL).