XSLT: Renommer attribut si existe pas

Question

J'ai beaucoup de fichiers XML qui contiennent des attributs d'une valeur mal orthographié:

<Part id="1"> 
    <Attribute Name="Colo" Value="Red" /> 
</Part> 

Colo devrait être Color. Maintenant, dans certains fichiers cela a été corrigé manuellement, puis les deux attributs existent:

<Attribute Name="Colo" Value="Red" /> 
<Attribute Name="Color" Value="Blue" /> 

J'ai une transformation XSL qui renomme l'attribut Colo-Color mais je ne sais pas comment éviter que lorsque l'attribut corrigé existe déjà.

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="Attribute/@Name[. = 'Colo']"> 
    <xsl:attribute name="Name"> 
     <xsl:value-of select="'Color'"/> 
    </xsl:attribute> 
</xsl:template> 

Comment ne pas renommer s'il y a déjà l'attribut correct?

Answer 1

Je pense que vous voulez faire:

XSLT 1,0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<!-- identity transform --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="Attribute[@Name = 'Colo']"> 
    <xsl:if test="not(../Attribute[@Name = 'Color'])"> 
     <Attribute Name="Color" Value="{@Value}" /> 
    </xsl:if> 
</xsl:template> 

</xsl:stylesheet> 

Cela modifiera l'élément Attribute avec le nom mal orthographié si elle ne possède pas de frères et soeurs avec le nom correct; sinon, il va simplement l'enlever.