Comment puis-je ajouter des caractères à une ligne dans un fichier?

Question

J'ai un fichier CSV qui a été extrait d'un système de ticketing (je n'ai aucun accès direct à la base de données) et j'ai besoin d'ajouter deux colonnes à une autre base de données avant de créer des rapports dans Excel.

J'utilise Perl pour extraire des données de l'autre base de données et je souhaite simplement ajouter les colonnes supplémentaires à la fin de chaque ligne lorsque je traite le fichier.

Y at-il un moyen de le faire sans avoir à créer un nouveau fichier? La structure de base est:

foreach $line (@lines) { 
    my ($vars here....) = split (',',$line); 
    ## get additional fields 
    ## append new column data to line 
} 

Answer 1

Vous pouvez utiliser Tie :: File (dans le noyau Perl depuis Perl 5.8) pour modifier un fichier en place:

#!/usr/bin/perl 

use strict; 
use warnings; 

use Tie::File; 


my $file = shift; 

tie my @lines, "Tie::File", $file 
    or die "could not open $file: $!\n"; 

for my $line (@lines) { 
    $line .= join ",", '', get_data(); 
} 

sub get_data { 
    my $data = <DATA>; 
    chomp $data; 
    return split /-/, $data 
} 

__DATA__ 
1-2-3-4 
5-6-7-8 

Vous pouvez également utiliser en place-édition avec le @ARGV/<> astuce en définissant $^I:

#!/usr/bin/perl 

use strict; 
use warnings; 

$^I = ".bak"; 

while (my $line = <>) { 
    chomp $line; 
    $line .= join ",", '', get_data(); 
    print "$line\n"; 
} 

sub get_data { 
    my $data = <DATA>; 
    chomp $data; 
    return split /-/, $data 
} 

__DATA__ 
1-2-3-4 
5-6-7-8 

Answer 2

Tenir compte en utilisant l'option -i modifier <> fichiers en place.

Answer 3

Vous pouvez regarder DBD::CSV pour traiter le fichier comme s'il s'agissait d'une base de données (qui traiterait également des caractères spéciaux d'échappement pour vous).

Answer 4

En dépit de toutes les belles interfaces, vous devez éventuellement lire le fichier ligne par ligne. Vous pourriez même devoir faire plus que si certains champs entre guillemets peuvent avoir des retours à la ligne incorporés. Utilisez quelque chose qui connaît CSV pour éviter certains de ces problèmes. Text::CSV_XS devrait vous épargner la plupart des tracas des cas impairs.