D'où vient _ _ dans cette boucle forl foreach?

Question

J'ai trouvé ceci dans Mail::IMAPClient. D'où vient le $_ en $SEARCH_KEYS{ uc($_) }?

sub _quote_search { 
    my ($self, @args) = @_; 
    my @ret; 
    foreach my $v (@args) { 
     if (ref($v) eq "SCALAR") { 
      push(@ret, $$v); 
     } 
     elsif (exists $SEARCH_KEYS{ uc($_) }) { 
      push(@ret, $v); 
     } 
     elsif (@args == 1) { 
      push(@ret, $v); # <3.17 compat: caller responsible for quoting 
     } 
     else { 
      push(@ret, $self->Quote($v)); 
     } 
    } 
    return @ret; 
} 

Answer 1

Cela me semble comme une faute de frappe où l'auteur converti un anonyme pour boucle foreach (@args) à un avec un itérateur explicite variables foreach my $v (@args) et a oublié de convertir toutes les incidences de $_-$v.

Vous devriez probablement déposer un bogue sur la distribution sur CPAN.

Answer 2

Même s'il s'agit probablement d'un bug, voyons comment se comporte ce code.

La valeur de $_ sera déterminée par la portée dynamique actuelle. Qu'est-ce que cela signifie est que $_ aura n'importe quelle valeur (la copie de la portée dynamique de) $_ a dans le sous-programme appelant.

Ainsi, par exemple si je dois:

for (1 .. 5) { 
    foo(); 
    bar(); 
} 

sub foo { 
    print "\$_ = $_\n"; 
} 

sub bar { 

    for ('a' .. 'c') { 
     foo(); 
    } 
} 

Vous obtenez une sortie comme:

$_ = 1 
$_ = a 
$_ = b 
$_ = c 
$_ = 2 
$_ = a 
$_ = b 
$_ = c 
... 

Il est un peu plus étrange en Perl 5.10 et plus, où un $_ lexical existe.

for (1 .. 5) { 
    foo(); 
    bar(); 
} 

sub foo { 
    print "\$_ = $_\n"; 
} 

sub bar { 
    my $_; 
    for ('a' .. 'c') { 
     foo(); 
    } 
} 

Exécuter ce et obtenez:

$_ = 1 
$_ = 1 
$_ = 1 
$_ = 1 
$_ = 2 
$_ = 2 
$_ = 2 
$_ = 2 

Comme vous pouvez le voir, si ce n'est pas un bug, il est probablement une mauvaise idée.