Delphi DBGrid cellule non vide

Question

Dans mon formulaire, j'ai un TDBGRid, TDatasource, MessageTable et 2 bouton. J'ai un bouton pour ajouter une nouvelle ligne dans mon DBGRID:

MessageTable.Append; 
MessageTable.Edit; 
MessageTable.FieldByName('FieldName').AsString := sName; 
MessageTable.Post; 

Le second bouton permet de supprimer une ligne de courant:

MessageTable.Edit ; 
MessageTable.Delete ; 

Comment assurer que toutes les cellules non vides avant que le poste?

S'il y a une cellule vide, j'ai besoin d'ignorer cette rangée!

comment puis-je faire cela?

Answer 1

Vous devez utiliser les fonctionnalités que l'ensemble de données (dans ce cas, TTable) vous donne déjà au lieu d'essayer de réinventer la roue. TDataSet fournit un événement (OnBeforePost) spécialement conçu à cet effet.

Cliquez sur votre TTable, puis basculez vers l'onglet Evénements dans l'inspecteur d'objets. Recherchez l'événement OnBeforePost et double-cliquez dessus pour générer le shell d'événements dans l'éditeur de code. Vous verrez quelque chose comme ceci:

procedure TForm1.Table1BeforePost(DataSet: TDataSet); 
begin 
    // DataSet is the TDataSet (TTable, TQuery, TADOQuery, etc.) to which 
    // event is attached 
end; 

Vous pouvez faire toutes vos validations nécessaires avant qu'un enregistrement est en fait écrit à la base de données ici. Par exemple, si vous voulez vous assurer que chaque champ unique a quelque chose, vous pouvez le faire:

procedure TForm1.Table1BeforePost(DataSet: TDataSet); 
var 
    i: Integer; 
begin 
    // You can replace DataSet with your actual table variable name, but using it 
    // this way allows you to use this same event for more than one table if you want. 
    for i := 0 to DataSet.FieldCount - 1 do 
    if DataSet.Fields[i].IsNull then 
     raise Exception.CreateFmt('Field %s has no value', DataSet.Fields[i].FieldName); 
end; 

Si vous voulez vous assurer que seuls certains champs ont des valeurs, ou que la valeur est dans une certaine plage , vous pouvez accéder au champ directement:

procedure TForm1.Table1BeforePost(DataSet: TDataSet); 
begin 
    if DataSet.FieldByName('MyField').IsNull then 
    Abort; // This silently cancels the post without telling the user  
    if DataSet.FieldByName('AField').AsInteger = 0 then 
    raise Exception.Create('AField must not be 0'); 
end; 

maintenant, vous ne devez pas faire quoi que ce soit dans votre TDBGrid. Si l'utilisateur tape DownArrow sur la dernière ligne et qu'une nouvelle ligne est insérée, et qu'ils entrent des données incomplètes ou erronées, les événements ci-dessus s'en occuperont. Ils fonctionneront également si vous utilisez deux boutons (un pour insérer ou modifier et l'autre pour publier), car les événements géreront tout le reste.

procedure TForm1.ButtonInsertClick(Sender: TObject); 
begin 
    Table1.Insert; // Or Append - if you have an index on the table they're the same thing 
end; 

procedure TForm1.ButtonPostClick(Sender: TObject); 
begin 
    Table1.Post; // This is 100% of the code you need here 
end;