construire une table de hachage avec gensym et macrolet

Question

Je suis en train de construire une table de hachage (entre autres actions) tandis que read ing. Je ne veux pas que la table de hachage ait une portée globale (encore), donc je le fais avec une macro et gensym. À l'intérieur de la macro x, je définis une macro s qui est similaire à setf, mais définit une entrée dans une table de hachage au lieu de définir un symbole quelque part. Ça explose. Je pense que je comprends le message d'erreur, mais comment puis-je le faire fonctionner?

Le code:

#!/usr/bin/clisp -repl 

(defmacro x (&rest statements) 
    (let ((config-variables (gensym))) 
    `(macrolet ((s (place value) 
        (setf (gethash 'place ,config-variables) value))) 
     (let ((,config-variables (make-hash-table :test #'eq))) 
     (progn ,@statements) 
     ,config-variables)))) 

(defun load-config() 
    (let ((config-file-tree (read *standard-input*))) 
    (eval config-file-tree))) 

(defun load-test-config() 
    (with-input-from-string (*standard-input* "(x (s fred 3) (s barney 5))") 
    (load-config))) 

(load-test-config) 

La sortie:

*** - LET*: variable #:G12655 has no value 
The following restarts are available: 
USE-VALUE  :R1  Input a value to be used instead of #:G12655. 
STORE-VALUE :R2  Input a new value for #:G12655. 
SKIP   :R3  skip (LOAD-TEST-CONFIG) 
STOP   :R4  stop loading file /u/asterisk/semicolon/build.l/stackoverflow-semi 

Answer 1

Dans un macrolet vous êtes aussi bien la définition d'une macro, de sorte que les règles habituelles applicables, à savoir que vous avez à BACKQUOTE expressions, qui sont à évaluer à l'exécution. Comme ceci:

(defmacro x (&rest statements) 
    (let ((config-variables (gensym))) 
    `(macrolet ((s (place value) 
       `(setf (gethash ',place ,',config-variables) ,value))) 
     (let ((,config-variables (make-hash-table :test #'eq))) 
     (progn ,@statements) 
     ,config-variables)))) 

Answer 2

Juste deviner ce que Bill pourrait vraiment vouloir. Disons qu'il veut un mappage de certaines clés à certaines valeurs en tant que configuration dans un fichier.

Voici la procédure.

• ouvrir un flux de données
• lire comme une s-expression
• marcher les données et remplir une table de hachage table

Exemple code:

(defun read-mapping (&optional (stream *standard-input*)) 
    (destructuring-bind (type &rest mappings) (read stream) 
    (assert (eq type 'mapping)) 
    (let ((table (make-hash-table))) 
     (loop for (key value) in mappings 
      do (setf (gethash key table) value)) 
     table))) 

(defun load-config() 
    (read-mapping)) 

(defun load-test-config() 
    (with-input-from-string (*standard-input* "(mapping (fred 3) (barney 5))") 
    (load-config))) 

(load-test-config) 

Utilisation:

CL-USER 57 > (load-test-config) 
#<EQL Hash Table{2} 402000151B> 

CL-USER 58 > (describe *) 

#<EQL Hash Table{2} 402000151B> is a HASH-TABLE 
BARNEY  5 
FRED  3 

Avantages:

• aucune macro
• données ne soit pas encodées dans le code source et Generated code source
• aucune évaluation (! De sécurité) par l'intermédiaire EVAL nécessaires
• pas de code objet ballonnement via des macros qui sont en expansion à un plus grand code
• abstraction fonctionnelle
• beaucoup plus facile à comprendre et déboguer

Sinon j'écrirais une macro de lecture pour { de telle sorte que {(fred 3) (barney 5)} serait directement lu comme une table de hachage.

---

Si vous voulez avoir des valeurs calculées:

(defun make-table (mappings &aux (table (make-hash-table))) 
    (loop for (key value) in mappings 
     do (setf (gethash key table) (eval value))) 
    table) 

CL-USER 66> (describe (make-table '((fred (- 10 7)) (barney (- 10 5))))) 

#<EQL Hash Table{2} 4020000A4B> is a HASH-TABLE 
BARNEY  5 
FRED  3 

tournant qui dans une macro:

(defmacro defmapping (&body mappings) 
    `(make-table ',mappings)) 

(defmapping 
    (fred 3) 
    (barney 5))