Moose: Array of Objects-> loop through Attribut

Question

Je suis nouveau à Perl Moose, et j'essaie d'accomplir cette tâche simple. J'ai ma classe Moose « TestObject » définis:

package TestObject; 
use Moose; 
use namespace::autoclean; 

has 'Identifier' => (is =>'ro',isa=>'Str'); 

around BUILDARGS => sub 
{ 
    my $orig = shift; 
    my $class = shift; 

    if (@_ == 1 && ! ref $_[0]) { 
     return $class->$orig(Identifier => $_[0]); 
    } 
    else { 
     return $class->$orig(@_); 
    } 
}; 
__PACKAGE__->meta->make_immutable; 
1; 

Dans un autre script que je suis en train d'accéder à l'attribut « Identifier » directement à partir d'un tableau de « TestObjects »:

use TestObject; 
use experimental 'smartmatch'; 
my @aArray1=(TestObject->new("z003"),TestObject->new("t302"),TestObject->new("r002")); 
my $sIdent="t302"; 
if($sIdent~~@aArray1->Identifier) 
{ 
    print "Element with Identifier".$sIdent." found."; 
} 

Ce n » t travail. Je pourrais mettre en œuvre une solution de contournement comme ceci:

my @aIdent=(); 
foreach my $sObject(@aArray1) 
{ 
    push(@aIdent,$sObject->Identifier); 
} 
if($sIdent~~@aIdent) 
{ 
    print "Element with Identifier".$sIdent." found."; 
} 

mais cela ne semble pas être la solution la plus élégante. Quelle est la solution la plus élégante pour résoudre ce problème?

Answer 1

Ne faites pas cela avec l'opérateur smartmatch. C'est expérimental pour une raison, et il pourrait être retiré des futures versions de Perl, ou changer la façon dont cela fonctionne, comme c'est déjà fait.

Au lieu de cela, cela peut être réalisé avec un simple grep.

my @aArray1 = ( 
    TestObject->new("z003"), 
    TestObject->new("t302"), 
    TestObject->new("r002"), 
); 

my $sIdent = "t302"; 
if (grep { $_->Identifier eq $sIdent } @aArray1) { 
    print "Element with Identifier" . $sIdent . " found."; 
} 

Si vous voulez que, pour être un peu plus courte, vous pouvez également utiliser first from List::Util. C'est un peu plus rapide car cela arrêtera de s'occuper du premier match.

use List::Util 'first'; 
my @aArray1 = ( 
    TestObject->new("z003"), 
    TestObject->new("t302"), 
    TestObject->new("r002"), 
); 

my $sIdent = "t302"; 
if (first { $_->Identifier eq $sIdent } @aArray1) { 
    print "Element with Identifier" . $sIdent . " found."; 
} 

---

Quelques mots de conseils sur votre code:

• Ne pas nommer jamais quoi que ce soit de classe avec objet. Cela va vous embrouiller, futur vous et le gars de la maintenance. Si vous ne comprenez pas la différence entre classe et objet, lire à ce sujet s'il vous plaît.
• Les noms de variables et les fonctions en Perl sont toujours écrits en minuscules par convention, et nous utilisons snake case. Camel case est réservé pour les noms de paquets.