Comment renvoyer un résultat d'une fonction VBA

Question

Comment renvoyer un résultat d'une fonction?

Par exemple:

Public Function test() As Integer 
    return 1 
End Function 

Cela donne une erreur de compilation.

Comment faire pour que cette fonction renvoie un nombre entier?

Answer 1

Pour les types de retour non-objet, vous devez affecter la valeur au nom de votre fonction, comme ceci:

Public Function test() As Integer 
    test = 1 
End Function 

Exemple d'utilisation:

Dim i As Integer 
i = test() 

Si la fonction retourne un objet le type, vous devez utiliser le mot-clé Set comme ceci:

Public Function testRange() As Range 
    Set testRange = Range("A1") 
End Function 

Exemple d'utilisation:

Dim r As Range 
Set r = testRange() 

Notez que l'attribution d'une valeur de retour au nom de la fonction n'arrête pas l'exécution de votre fonction. Si vous voulez quitter la fonction, vous devez indiquer explicitement Exit Function. Par exemple:

Function test(ByVal justReturnOne As Boolean) As Integer 
    If justReturnOne Then 
     test = 1 
     Exit Function 
    End If 
    'more code... 
    test = 2 
End Function 

Documentation: http://msdn.microsoft.com/en-us/library/office/gg264233%28v=office.14%29.aspx

Answer 2

fonctions VBA traitent le nom de la fonction elle-même comme une sorte de variable. Ainsi, au lieu d'utiliser une déclaration « return », vous dites simplement:

test = 1 

avis, cependant, que cela ne rompt pas la fonction. Tout code après cette instruction sera également exécuté. Ainsi, vous pouvez avoir de nombreuses instructions d'assignation qui assignent des valeurs différentes à test, et quelle que soit la valeur lorsque vous atteignez la fin de la fonction sera la valeur retournée.

Answer 3

suffit de positionner la valeur de retour au nom de la fonction est toujours pas exactement les mêmes que Java (ou autre) déclaration return, car en java, return quitte la fonction, comme ceci:

public int test(int x) { 
    if (x == 1) { 
     return 1; // exits immediately 
    } 

    // still here? return 0 as default. 
    return 0; 
} 

Dans VB, l'équivalent exact prend deux lignes si vous ne définissez pas la valeur de retour à la fin de votre fonction. Ainsi, en VB le corollaire exact ressemblerait à ceci:

Public Function test(ByVal x As Integer) As Integer 
    If x = 1 Then 
     test = 1 ' does not exit immediately. You must manually terminate... 
     Exit Function ' to exit 
    End If 

    ' Still here? return 0 as default. 
    test = 0 
    ' no need for an Exit Function because we're about to exit anyway. 
End Function 

Puisque tel est le cas, il est aussi agréable de savoir que vous pouvez utiliser la variable de retour comme toute autre variable dans la méthode.Comme ceci:

Public Function test(ByVal x As Integer) As Integer 

    test = x ' <-- set the return value 

    If test <> 1 Then ' Test the currently set return value 
     test = 0 ' Reset the return value to a *new* value 
    End If 

End Function 

Ou, l'extrême exemple de la façon dont la variable de retour fonctionne (mais pas nécessairement un bon exemple de la façon dont vous devriez le code réellement) -le qui vous tiendra la nuit:

Public Function test(ByVal x As Integer) As Integer 

    test = x ' <-- set the return value 

    If test > 0 Then 

     ' RECURSIVE CALL...WITH THE RETURN VALUE AS AN ARGUMENT, 
     ' AND THE RESULT RESETTING THE RETURN VALUE. 
     test = test(test - 1) 

    End If 

End Function 

Answer 4

le code ci-dessous stocke la valeur de retour à la variable retVal puis MsgBox peut être utilisé pour afficher la valeur:

Dim retVal As Integer 
retVal = test() 
Msgbox retVal