Pourquoi cette instruction en Perl n'est-elle pas compilée?

Question

Cela échoue:

my @a = ("a", "b", "c", "d", "e"); 
my %h = map { "prefix-$_" => 1 } @a; 

avec cette erreur:

Not enough arguments for map at foo.pl line 4, near "} @a" 

mais cela fonctionne:

my @a = ("a", "b", "c", "d", "e"); 
my %h = map { "prefix-" . $_ => 1 } @a; 

pourquoi?

Answer 1

Parce que Perl devine un EXPR (une référence de hachage, par exemple) au lieu d'un BLOCK. Cela devrait fonctionner (notez le symbole '+'):

my @a = ("a", "b", "c", "d", "e"); 
my %h = map { +"prefix-$_" => 1 } @a; 

Voir http://perldoc.perl.org/functions/map.html.

Answer 2

De perldoc -f map:

  "{" starts both hash references and blocks, so "map { ..." 
      could be either the start of map BLOCK LIST or map EXPR, LIST. 
      Because perl doesn’t look ahead for the closing "}" it has to 
      take a guess at which its dealing with based what it finds just 
      after the "{". Usually it gets it right, but if it doesn’t it 
      won’t realize something is wrong until it gets to the "}" and 
      encounters the missing (or unexpected) comma. The syntax error 
      will be reported close to the "}" but you’ll need to change 
      something near the "{" such as using a unary "+" to give perl 
      some help: 

      %hash = map { "\L$_", 1 } @array # perl guesses EXPR. wrong 
      %hash = map { +"\L$_", 1 } @array # perl guesses BLOCK. right 
      %hash = map { ("\L$_", 1) } @array # this also works 
      %hash = map { lc($_), 1 } @array # as does this. 
      %hash = map +(lc($_), 1), @array # this is EXPR and works! 
      %hash = map (lc($_), 1), @array # evaluates to (1, @array) 

      or to force an anon hash constructor use "+{" 

      @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end 

      and you get list of anonymous hashes each with only 1 entry. 

Answer 3

Je préfère écrire que

my %h = map { ("prefix-$_" => 1) } @a; 

pour montrer l'intention, que je retourne une liste 2 éléments.

Answer 4

En outre, l'autre façon de faire ce que vous faites, initialiser le hachage, vous pouvez faire comme ceci:

my @a = qw(a b c d e); 
my %h; 
@h{@a} =(); 

Cela crée des entrées FNUD pour chacune des cinq touches. Si vous voulez leur donner toutes les vraies valeurs, faites-le.

@h{@a} = (1) x @a; 

Vous pouvez également le faire explicitement avec une boucle;

@h{$_} = 1 for @a; 

Answer 5

Je pense que

map { ; "prefix-$_" => 1 } @a; 

est plus idiomatiques, jusqu'à préciser qu'il est un bloc d'instructions et non une référence de hachage. Vous commencez juste avec une déclaration nulle.