Comment puis-je utiliser des hachages comme arguments pour des sous-routines en Perl?

Question

J'ai une fonction qui fait des calculs et passe ensuite quelques propriétés dans une autre sous-routine comme ceci:

sub get_result { 
    my $id = 1;  
    my %diet = (result => 28, 
       verdict => 'EAT MORE FRUIT DUDE...'  
       ); 

    my %iq = (result => 193, 
       verdict => 'Professor Einstien' 
      );   
    print_result($id, %diet, %iq); 
} 

sub print_result {  
    my $id = shift;  
    my %d = @_;  
    my %i = @_;  

    print "IQ: $id\n";  
    print "DIET RESULT: $d{result}\n";  
    print "DIET VERDICT: $d{verdict}\n";  
    print "IQ RESULT: $i{result}\n";  
    print "IQ VERDICT: $i{verdict}\n";  
}  

Mon problème est que les résultats imprimés en (résultat DIET, DIET VERDICT) et (IQ POINTAGE, IQ RÉSULTAT) sont les mêmes. Comme si les variables% d et% i étaient peuplées avec les mêmes variables. Des idées pourquoi c'est?

Si je tente de déplacer les trois variables comme ceci:

my $id = shift;  
my %d = shift;  
my %i = shift; 

Je reçois l'erreur suivante:

Odd number of elements in hash assignment 

Answer 1

Lorsque vous passez un tableau (ou hachage) à un sous-programme, la sous-routine obtenir une liste des valeurs (ou paires de valeurs clés). C'est pourquoi vous ne pouvez pas passer deux tableaux (ou deux hachages), car le sous-programme ne saura pas où le premier tableau se termine et le second commence.

Pour contourner ce problème, vous devez passer des références à la place:

my %hash1 = (foo => 'bar'); 
my %hash2 = (bar => 'baz'); 
subroutine(\%hash1, \%hash2); 

sub subroutine { 
    my ($hashref1, $hashref2) = @_; 
    print $hasref1->{foo}, $hashref2->{bar}; 
} 

PS: En dehors du problème conceptuel, votre code comporte également ceci:

my %d = @_;  
my %i = @_;  

Si% d et% On m'a attribué la même valeur à tous les deux, cela ne devrait pas surprendre quand ils sont identiques par la suite.

Answer 2

Lorsque vous passez %diet et %iq, ils ont tous deux s'aplatissent dans le tableau de arg, donc dans votre print_result, %d contient tous les éléments %diet et %iq.

Résoudre des problèmes, utilisez références du %diet et %iq:

print_result($id, \%diet, \%iq); 

Puis, en print_result:

my $id = shift; 
my %d = %{+shift}; 
my %i = %{+shift}; 

Answer 3

use strict; 
use warnings; 

sub get_result { 

    ... 

    print_result($id, \%diet, \%iq); 
    # or 
    print_result($id, {%diet}, {%iq}); 
} 


sub print_result{ 
    my($id, $diet_h, $iq_h) = @_; 
    my %diet = %$diet_h; 
    my %iq = %$iq_h; 

    ... 

} 

Ou:

use strict; 
use warnings; 

sub print_result($\%\%); 

sub get_result{ 

    ... 

    print_result($id, %diet, %iq); 
} 

sub print_result($\%\%){ 
    my($id, $diet_h, $iq_h) = @_; 
    my %diet = %$diet_h; 
    my %iq = %$iq_h; 

    ... 

} 

Answer 4

Vous voudrez peut-être consulter mon livre Intermediate Perl, dont environ un tiers traite de références et comment travailler avec elles. Cela inclut le passage de structures de données complexes dans des sous-routines ainsi que d'autres façons dont les références vous facilitent la vie. :)

some_sub(\%hash); 
some_sub({ key => 'value' }); 
some_sub($hash_ref); 

sub some_sub { 
    my($hash_ref) = @_; 

    ... 
    }