Distribution spécifiée n'est pas valide lorsque DataBind à Nullable DateTimeOffset et le champ est NULL

Question

J'ai créé un CompositeControl simple et exposé une propriété Nullable DateTimeOffset. Je suis liant le contrôle à un champ DateTimeOffset SQL Server à l'aide

DateTimeOffset='<%# Bind("myDateTimeOffsetField") %>' 

Cela fonctionne très bien lorsque le champ DateTimeOffset a une valeur. Mais lorsque le champ est NULL, j'obtiens une erreur "Cast spécifié n'est pas valide". Comment puis-je arrêter cette erreur et définir ma propriété sur Nothing lorsque le champ est NULL? Je pensais que ce serait le comportement par défaut!

définition de la propriété est:

Public Property DateTimeOffset As DateTimeOffset? 

commentaire plus tard:

J'ai trouvé que cela fonctionne si je change d'utiliser Bind à:

DateTimeOffset='<%# iif(IsDbNull(Eval("myDateTimeOffsetField")), Nothing, Eval("myDateTimeOffsetField")) %>' 

Mais je don 't get "myDateTimeOffsetField" passé comme un argument dans l'événement FormView.ItemUpdating (oui, c'est dans un contrôle FormView) depuis ASP.NET suppose que je ne suis pas t liant à la base de données.

code réel (Ajouté par demande)

C'est la propriété de mon contrôle composite que je suis en train de se lier à:

Public Property DateTimeOffset As DateTimeOffset? 
Get 
    Return CType(ViewState("DTO"), DateTimeOffset?) 
End Get 
Set(value As DateTimeOffset?) 
    ViewState("DTO") = value 
End Set 
End Property 

Heres le balisage pour la liaison. Le contrôle est dans le EditItemTemplate d'un FormView qui est lié à une source de données SQL retournant un champ appelé [dtoMldRejOn] avec une valeur facultative DateTimeOffset.

<APS:DateTimeOffsetControl runat="server" id="dtocMldRejOn" TextBoxCssClass="inputdatetime" ValidationGroup="vw1" FieldName="<%$ Resources: Resource, rxgFrom %>" DateTimeOffset='<%# Bind("dtoMldRejOn") %>' WindowsTimeZoneID="<%# me.WindowsTimeZoneID %>" IsRequired="false" /> 

Comme vous pouvez le voir, mon contrôle Composite sert à gérer les valeurs DateTimeOffset. Tout fonctionne très bien, à moins que le champ DateTimeOffset [dtoMldRejOn] de la base de données soit NULL, alors j'obtiens l'exception.

Answer 1

Je n'ai jamais créé des contrôles bindable avant, mais je voudrais faire des suggestions. Que diriez-vous de définir votre propriété DateTimeOffset pour être de type Object. De cette façon, la propriété acceptera tous les types de données, y compris DBNull.

Et une fois dans le code Set, vérifiez si la valeur transmise est DBNull.Value. Si oui, créez un DataTimeOffset vide? objet et enregistrez-le dans ViewState.

En cas de valeurs non DBNull, erreur de renvoi si elle ne peut pas être convertie en date/heure.

Je n'ai pas essayé ceci cependant je ne sais pas si cela fonctionnera ou pas.

################ ################ MISE À JOUR ANSWER

Ma suggestion est, vous créez 2 propriétés comme suit:

Public Property DateTimeOffset() As DateTimeOffset? 
    Get 
     Return DirectCast(ViewState("DTO"), DateTimeOffset?) 
    End Get 
    Set(ByVal Value As DateTimeOffset?) 
     ViewState("DTO") = Value 
    End Set 
End Property 

<Bindable(True, BindingDirection.TwoWay)> 
Public Property DbDateTimeOffset As Object 
    Get 
     Return Me.DateTimeOffset 
    End Get 
    Set(value As Object) 
     If IsDBNull(value) OrElse value Is Nothing Then 
      Me.DateTimeOffset = New DateTimeOffset? 
     Else 
      Me.DateTimeOffset = DirectCast(value, DateTimeOffset?) 
     End If 
    End Set 
End Property 

donc, dans votre balisage, la liaison sera à la DbDateTimeOffset propriété:

DbDateTimeOffset='<%# Bind("myDateTimeOffsetField") %>' 

Alors que dans le code derrière, vous pouvez utiliser l'autre propriété pour lire la propriété avec avoir à jeter.

Answer 2

Basé sur this post,

Je pense que vous avez juste besoin de marquer votre propriété avec l'attribut Bindable:

<System.ComponentModel.Bindable(True)> _ 
Public Property DateTimeOffset As DateTimeOffset? 

Answer 3

Le problème est que DbNull est différent de Nothing et vous devez écrire explicitement quelque part dans votre code. Ma première idée ici était d'utiliser les événements de liaison pour ajouter la valeur. Donc, si vous vous gardez code comme ceci:

DateTimeOffset='<%# iif(IsDbNull(Eval("myDateTimeOffsetField")), Nothing, Eval("myDateTimeOffsetField")) %>' 

Vous pouvez ajouter manuellement le paramètre DateTimeOffset dans les événements Updating avant que le liaison (je peux mettre à jour la réponse plus tard avec plus de détails si vous voulez)

Quoi qu'il en soit, après avoir lu votre code plus attentivement, je pensais que peut-être le CType ne cast pas correctement. Avez-vous essayé de remplacer votre Get avec quelque chose comme ça?

Get 
    Return If(IsDbNull(ViewState("DTO")), Nothing, CType(ViewState("DTO"), DateTimeOffset?)) 
End Get 

Answer 4

Votre code avec iif ... Fonctionne pour moi.
J'ai créé un contrôle de test et une version de page avec du code derrière les pages (j'ai aussi testé le code derrière la version mais celui-ci est plus facile à publier). J'ai le cadre cible VS2010 est de 4,0. D'abord le contrôle (TstNullableCtrl.ascx):

<%@ Control Language="vb" AutoEventWireup="false" %> 
<script runat="server"> 
    Public Property DateTimeOffset As DateTimeOffset? 
</script> 
<div ID="Label1" runat="server" > 
<%= If(DateTimeOffset.HasValue, DateTimeOffset.ToString, "Empty")%> 
</div> 

et la page - une table avec deux lignes et deux colonnes lié à DataGrid (TstNullablePage.aspx):

<%@ Page Language="vb" AutoEventWireup="false" %> 
<%@ Import Namespace="System.Data"%> 
<%@ Register src="TstNullableCtrl.ascx" tagname="TstNullableCtrl" tagprefix="uc1" %> 
<script runat="server"> 
    Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load 
     Dim tbl As New DataTable 
     tbl.Columns.Add(New DataColumn("id", GetType(Integer)) With {.AutoIncrement = True}) 
     tbl.Columns.Add(New DataColumn("myDateTimeOffsetField", GetType(DateTimeOffset))) 
     Dim row As DataRow 
     row = tbl.NewRow : row("myDateTimeOffsetField") = DateTimeOffset.Now 
     tbl.Rows.Add(row) 
     row = tbl.NewRow : row("myDateTimeOffsetField") = DBNull.Value 
     tbl.Rows.Add(row) 
     tstgrd.DataSource = tbl : tstgrd.DataBind() 
    End Sub 
</script> 
<html> 
<body> 
    <form id="form1" runat="server"> 
     <asp:datagrid ID="tstgrd" runat="server"> 
     <Columns> 
     <asp:TemplateColumn HeaderText="Offset"> 
      <itemtemplate>  
      <uc1:TstNullableCtrl ID="WithNullableDate1" runat="server" 
       DateTimeOffset='<%# iif(IsDbNull(Eval("myDateTimeOffsetField")), Nothing, Eval("myDateTimeOffsetField")) %>' /> 
      </itemtemplate> 
     </asp:TemplateColumn> 
     </Columns> 
     </asp:datagrid> 
    </form> 
</body> 
</html> 

Et résultat attendu (un La valeur lorsqu'il n'y a et 'vide' lorsqu'il est nulle)

Modifier

Cependant, je pense que pour « éviter des complications » meilleure solution est la suivante:

Public _DateTimeOffset As Object 
Public Property DateTimeOffset As Object 
Get 
    If IsDBnull(_DateTimeOffset) then Return Nothing 
    Return Ctype(_DateTimeOffset, DateTimeOffset?) 
End Get 
Set(value As Object) 
    _DateTimeOffset = value 
End Set 
End Property 

Answer 5

Je sais que cette question a été déjà répondu que je voudrais simplement documenter ma solution qui est entre ces deux réponses comme je l'ai suis tombé sur aujourd'hui:

Private _AssetId As Object 
<Bindable(True, BindingDirection.TwoWay)> 
Public Property AssetId() As Object 
    Get 
     If _AssetId Is Nothing Then     
      Return Nothing     
     Else 
      Return CType(_AssetId, Integer) 
     End If 
    End Get 
    Set(ByVal value As Object) 
     If value Is Nothing OrElse IsDBNull(value) OrElse CType(value, String) = "" Then 
      _AssetId = Nothing     
     Else 
      _AssetId = CType(value, Integer)     
     End If 
    End Set 
End Property