Corecursion ne se termine pas après un petit changement

Question

J'ai écrit une fonction dans Racket pour produire quelque chose de similaire à la fractale suivante.

(define CUT-OFF 5) 
(define CIRCLE-MODE "outline") 

(define (circle-fractal size colour) 
    (local [(define full-circle (circle size CIRCLE-MODE colour))] 

    (cond [(<= size CUT-OFF) full-circle] 
      [else 
      (overlay/align "middle" "middle" 
          full-circle 
          (beside (circle-fractal (/ size 2) colour) 
            (circle-fractal (/ size 2) colour)))]))) 

Il passe mes tests.

J'ai changé le code, pensant que ce qui suit serait plus lisible.

(define (circle-fractal size colour) 
    (local [(define full-circle (circle size CIRCLE-MODE colour)) 
      (define half-circle (circle-fractal (/ size 2) colour))] 

    (cond [(<= size CUT-OFF) full-circle] 
      [else 
      (overlay/align "middle" "middle" 
          full-circle 
          (beside half-circle half-circle))]))) 

Maintenant, la fonction ne se termine pas. La raquette atteint sa limite de mémoire sans sortie.

Est-ce que chaque appel corecursif approche d'une manière ou d'une autre le cas trivial après ce changement?

Answer 1

Dans la première version (circle-fractal (/ size 2) colour) est évaluée seulement si size > CUT-OFF. Dans la seconde, il est appelé indépendamment de la taille. De cette façon, vous avez perdu votre cas de base de récursivité.

Essayez:

(define (circle-fractal size colour) 
    (define full-circle (circle size CIRCLE-MODE colour)) 
    (cond [(<= size CUT-OFF) full-circle] 
     [else 
     (define half-circle (circle-fractal (/ size 2) colour)) 
     (overlay/align "middle" "middle" 
         full-circle 
         (beside half-circle half-circle))]))