Conversion d'ActionScript 2 de base en ActionScript 3 pour les animations de survol

Question

Donc, ce que j'essaie de faire devrait être simple. C'est simplement une animation de survol qui s'inverse lorsque l'utilisateur enlève la souris. Chose est, c'est en AS2 mais et je pense que pour terminer le projet, je vais en avoir besoin dans AS3. Quelqu'un peut-il donner quelques conseils sur la conversion de ce ...

stop(); 

this.onEnterFrame = function(){ 
if(rewind == true){ 
prevFrame(); 
} 
} 

this.onRollOver = function(){ 
rewind = false; 
play(); 
} 

this.onRollOut = function(){ 
rewind = true; 
} 

this.onRelease = function(){ 
getURL("http://www.google.com","_blank"); 
} 

... en AS3? Je serais extrêmement reconnaissant.

Answer 1

Si vos besoins de code sont limités à ceux-ci, vous devriez apprendre à le faire dans AS3 une fois pour toutes.

Voici exactement la même chose dans AS3

import flash.events.Event; 
import flash.events.MouseEvent; 
import flash.net.navigateToURL; 
import flash.net.URLRequest; 

stop(); 
addEventListener(Event.ENTER_FRAME, onEnterFrame); 
addEventListener(MouseEvent.MOUSE_OVER, onMouseOver); 
addEventListener(MouseEvent.MOUSE_OUT, onMouseOut); 
addEventListener(MouseEvent.CLICK, onClick); 

var rewind:Boolean = false; 

function onEnterFrame(event:Event):void 
{ 
    if (rewind == true) { 
     prevFrame(); 
    } 
} 

function onMouseOver(event:MouseEvent):void 
{ 
    rewind = false; 
    play(); 
} 

function onMouseOut(event:MouseEvent):void 
{ 
    rewind = true; 
} 

function onClick(event:MouseEvent):void 
{ 
    navigateToURL(new URLRequest("http://www.google.com"),"_blank"); 
} 

S'il vous plaît noter que au lieu de créer un écouteur à un événement (survolez par exemple) en écrivant this.onRollOver = function(), vous avez fait appeler addEventListener (ce qui est assez logique), spécifiez l'événement que vous souhaitez écouter et créez une fonction appelée lorsque cet événement est intercepté.

Il y a aussi une autre différence dans getURL ->navigateToURL, mais je pense que vous n'avez pas besoin d'autres explications pour elle :)

En guise de remerciement, je vous apprécie vraiment lire ce code et essayez apprendre au lieu de le copier/coller grossièrement. Mais bon, vous êtes libre!