Gnuplot: Histogrammes empilés multiples, chaque groupe utilisant la même clé

Question

J'essaye de créer un graphique avec plusieurs histogrammes empilés comme l'exemple 8 here. Mais pour mes données, chaque groupe a les mêmes quatre catégories.

Comment puis-je changer les couleurs et la clé pour que les couleurs vont Rouge, Vert, Bleu, Rose pour chaque colonne empilés? Et donc la clé a seulement une copie de chacune des 4 choses que je suis en train de comploter?

Voici la ligne que je utilise pour tracer:

plot newhistogram "1", 'addresses.dat' using 2:xtic(1) t 2, '' u 3 t 3, \ 
'' u 4 t 4, '' u 5 t 5, newhistogram "2", '' u 6 t 6, '' u 7 t 7, '' u 8 t 8,\ 
'' u 9 t 9 

Mes données sont dans le même format que l'exemple que je lien ci-dessus:

Address PAL_Code BASH App Kernel PAL_Code BASH App Kernel 
FFT 1 1 2 2 1 1 3 4 
RADIX 1 2 3 4 1 2 4 5 
LU 1 3 4 5 1 3 5 6 

Merci beaucoup si vous peut aider!

Answer 1

utiliser le spécificateur lt derrière newhistogram afin de spécifier la première couleur que gnuplot doit utiliser. J'ai écrit un petit script qui pourrait fait ce que vous voulez;)

set style data histogram 
set style histogram rowstack gap 1 
set style fill solid border -1 
set boxwidth 0.9 
set key autotitle columnheader 
set key outside below center horizontal 
plot newhistogram "1" lt 1, 'addresses.dat' u 2:xtic(1), '' u 3, '' u 4, '' u 5,\ 
newhistogram "2" lt 1, 'addresses.dat' u 6:xtic(1) notitle, '' u 7 notitle, \ 
'' u 8 notitle, '' u 9 notitle 

espoir qui aide

Cherio
Woltan