Invite Monad dans Purescript

Question

Je travaille à travers la définition de Prompt et son Bind instance décrit here et essayait de comprendre comment cela ressemblerait dans Purescript. J'utilise Purescript.Exists pour le type existentiel. Mon défintion est alors:

data PromptAskF p r a 
    = PromptAskF (p a) (a -> Prompt p r) 

type PromptAsk p r = Exists (PromptAskF p r) 

data Prompt p r 
    = Ask (PromptAsk p r) 
    | Answer r 

instance bindPrompt :: Bind (Prompt p) where 
    bind (Answer x) k = k x 
    bind (Ask ask) k = ??? 

Je suis coincé sur l'écriture du en particulier, le cas Ask dans le cas Bind et je suis très confus au sujet des types lorsque vous travaillez avec runExists.

Comment écrire cette instance?

Merci,

Michael

Answer 1

Quelque chose comme ça devrait faire l'affaire:

data PromptAskF p r a 
    = PromptAskF (p a) (a -> Prompt p r) 

type PromptAsk p r = Exists (PromptAskF p r) 

mapPA 
    :: forall p r r' 
    . (forall a. (a -> Prompt p r) -> (a -> Prompt p r')) 
    -> PromptAsk p r 
    -> PromptAsk p r' 
mapPA f = runExists \(PromptAskF req cont) -> mkExists $ PromptAskF req (f cont) 

data Prompt p r 
    = Ask (PromptAsk p r) 
    | Answer r 

instance functorPrompt :: Functor (Prompt p) where 
    map f (Answer r) = Answer (f r) 
    map f (Ask ask) = Ask $ mapPA (map (map f)) ask 

instance applyPrompt :: Apply (Prompt p) where 
    apply = ap 

instance applicativePrompt :: Applicative (Prompt p) where 
    pure = Answer 

instance bindPrompt :: Bind (Prompt p) where 
    bind (Answer x) k = k x 
    bind (Ask ask) k = Ask $ mapPA (\cont ans -> cont ans >>= k) ask 

instance monadPrompt :: Monad (Prompt p) 

La fonction mapPA est une commodité pour la mise à jour la poursuite PromptAskF sans avoir à plusieurs reprises runExists/mkExists.