Pourrais-je mélanger des valeurs de données locales avec des valeurs renvoyées à partir de la base de données lors de l'utilisation de LINQ to SQL?

Question

Je crée un fichier xml avec LINQ comme suit ...

Public Sub CreateXml() 
     Dim db As New MDataContext 
     Dim Customers = <gallery columns="3" rows="3"> 
          <%= From customer In db.Customers _ 
           Select <customer> 
              <name><%= customer.CustName %></name> 
              <surname><%= customer.Surname %></surname> 
             </customer> %> 
         </gallery> 
     Customers.Save("d:\1.xml") 
    End Sub 

pourrais-je mélanger les valeurs locales avec celles renvoyées par la requête LINQ ... Quelque chose comme ce qui suit?

Public Sub CreateXml(ByVal **Col** As String, ByVal **Row** As String) 
     Dim db As New MDataContext 
     Dim Customers = <gallery columns="& **Col** &" rows="& **Row** &"> 
          <%= From customer In db.Customers _ 
           Select <customer> 
              <name><%= customer.CustName %></name> 
              <surname><%= customer.Surname %></surname> 
             </customer> %> 
         </gallery> 

     Customers.Save("d:\1.xml") 
     Process.Start("d:\1.xml") 
    End Sub 

Answer 1

Vous devriez être en mesure d'intégrer les valeurs des deux variables comme vous le faites avec le customer.CustName et customer.Surname, par exemple

Public Sub CreateXml(ByVal cols As Integer, ByVal rows As Integer) 
    Dim db As New MDataContext 
    Dim Customers = <gallery columns="<%= cols %>" rows="<%= rows %>"> 
         <%= From customer In db.Customers _ 
          Select <customer> 
             <name><%= customer.CustName %></name> 
             <surname><%= customer.Surname %></surname> 
            </customer> %> 
        </gallery> 

    Customers.Save("d:\1.xml") 
    Process.Start("d:\1.xml") 
End Sub 

à proprement parler, vous devriez probablement faire un appel ToString() approprié, par exemple <%= cols.ToString(CultureInfo.InvariantCulture) %>. De cette façon, vous vous assurez que la modification n'introduit pas de boxe inutile et qu'elle est également indépendante de la culture du thread en cours d'exécution, bien que cette dernière ne soit pas susceptible d'affecter la variable Integer.